%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
% Cette police utilise le schéma (layout) des polices dcr, avec 
% les quelques modifications suivantes:
%
%    1) les caractères 128 à 188 (sauf 159), qui correspondent … 
%       des accents utilisés dans des langues "rares", sont 
%       employés: 
%         a) pour des ligatures calligraphiques ("queues", 
%            modifications après b, o et v, etc.) et des formes 
%             alternatives (lettres finales, etc.)
%           (caractéres utilisés: 
%          128 à 148 et  150 à 158)
%
%         b) pour une liste de caractères "bâtons" pour des 
%          "majuscules d'imprimerie" à la main; la macro \calli 
%           permet de les utiliser par la commande {\csc Nom}, par 
%           exemple, ce qui est compatible avec les polices 
%            usuelles "caps and smallcaps"; une police complète 
%           sera créée ult‚rieurement
%              (caractères utilisés: 160 à 188)
%
%    2) le caractère 018 (dont je ne voyais pas l'intérêt...)  
%       représente ici l'apostrophe "basse" (après
%       m', n', etc); la ligature est faite automatiquement 
%        (il suffit donc de taper m' pour obtenir m\char 018). 
%
%    3) les ligatures ff, fl, fi, ffl et ffi 
%      (caractères 27 … 31) sont inutiles (mais peuvent être
%       utilisées pour d'autres ligatures analogues...)
%
%    4) les autres ligatures des polices dcr (--,---, '', ``) sont 
%       implémentées, ainsi que  !`et ?` (qui ne figurent que dans 
%         les polices cmr), mais ces deux dernières ne
%        "marchent" que si la ponctuation est "inactive".
%     
%    5) les accents (positions 0,1,2, etc.) ne fonctionnent pas
%          bien, car les largeurs des caractŠres ont été
%          "trafiquées"; il vaut mieux utiliser les caractères
%         224 à 252, de toute fa‡on.
%
%%%%  (les 256 positions sont loin d'être toutes occupées, 
%%%%   mais l'essentiel est là!)
%
%  L'utilisation "TeX" doit être faite en combinaison avec le 
% schéma  de codage sur 8 bits, et les macros correspondantes 
% (ibmpc.tex, etc.); leur forme générale est, par exemple, 
% \catcode`\à=\active \def \à={\char 224 } (ou \def \à={^^e0}).
%  Mes propres macros prennent le relais (parce que je n'aime pas 
% les accents circonflexes des polices dcr, entre autres); c'est 
% ce qui explique la forme un peu redondante de la macro \calli,
%  qui "appelle" la fonte calligraphique, et redéfinit les 
% paramètres d'espacement, les abréviations courantes (\eme), etc.
%
%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  Cette fonte est le résultat de tâtonnements  expérimentaux avec
%  METAFONT;  il faut  donc un solide courage pour envisager de la 
%  modifier (ou même de la comprendre). On peut toutefois assez 
%  aisément changer la "taille" ("unit", quoique \magnification
%  marche aussi) , le facteur hauteur/largeur ("rapportwh"), l'in-
%  clinaison des caractères ("slant") et la graisse ("graisse", et 
%  peut-être aussi "fgras", "fdelie"); ces paramètres ont donc été  
%  regroupés dans le fichier calexpar.mf.
%
%   Le tracé "calligraphique" résulte essentiellement du programme
%   dyp (et de ses variantes dyb et dypm), surtout 
%   sensible à "angledyn"; "vitesse" "affine" le tracé, et "power" 
%   concentre ou diffuse les pleins.
%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%






%%%%%  Paramètres (supplémentaires; voir aussi calexpar) %%%%%%%%


ohaut:= unit;



slarge#:=1.8olarge#/5;
slarge:=1.8olarge/5;
inidelh:=0.2slarge;

def inipar=
ux:= unit/rapportwh;
uy:= unit;
sunit:=unit/10;

shaut:=ohaut/5;
delh:=inidelh;

delb:=-0.1slarge;
delg:=-0.2shaut;
deld:=0.1shaut;
pbas:=1.2ohaut;

lihaut:= 0.36 ohaut; % hauteur des liaisons
liangle:=55; %angle des liaisons

ihaut:= 1.35ohaut;% hauteur des accents
dhaut:= 2.2ohaut;% boucles hautes
evert:=1.3ohaut;
thaut:= 1.65ohaut;% d,t, etc.
dphaut:=dhaut-shaut;% variante...

plein:= 0.11cunit;
bar:=0.07 cunit;
mdel:=0.06 cunit;mdel#:=0.06cunit#;
midel:=0.055 cunit;
delie:=0.05 cunit;%0.04
hdel:=0.025cunit;%0.02





%construction des plumes

angledyn:=-20; 
% (l'angle d'inclinaison de la plume (plein maximum … cet angle,
 % d‚li‚ … a+180)
power:=1.7;%%%%%%%%%%%% vitesse de passage de plein à del
vitesse:=6;%%%%%%%%% nombre de points d'interpolation

enddef; 

inipar;
%%%%%%% avec cette approche, on peut modifier les paramètres %%%%%%%%% localement


pickup pencircle xscaled (plein/2) yscaled (hdel/2) rotated -10;
lpen1:=savepen;

pickup pencircle scaled plein;
lpen:=savepen;
pickup pencircle scaled 0.8plein;
lspen:=savepen;
pickup pencircle scaled 1.3plein;
llpen:=savepen;
pickup pencircle scaled bar;
mpen:=savepen;
pickup pencircle xscaled mdel yscaled hdel rotated 60;
mpen1:=savepen;
pickup pencircle scaled 0.7mdel;
mfpen:=savepen;
pickup pencircle scaled mdel;
mmfpen:=savepen;
pickup pencircle scaled delie;
fpen:=savepen;
pickup pencircle scaled hdel;
ffpen:=savepen;

pickup pencircle scaled thin;
spen:=savepen;

pickup pencircle scaled 4thin;
bpen:=savepen;


def dr(expr a)=
pickup bpen;
drawdot a; enddef;

def dynpa(expr p,n)(text list)=
numeric x.dy[];numeric y.dy[]; numeric x.dy[]l;
numeric y.dy[]l;numeric x.dy[]r;numeric y.dy[]r; ll:=length  p; path pwl;path pwr;pair odp;pair oodp;pair dp[];
k:=0;
for wide=list:
z.dy[k]=point (k *ll/(n-1)) of p;dp[k]:=direction (k*ll/(n-1)) of p;
penpos.dy[k](wide*delie,(angle(dp[k])-90));
k:=k+1;
endfor;
k:=0; 
pwl:=z.dy0l{dp0}..{dp1}z.dy1l;
pwr:=z.dy1r{-dp1}..{-dp0}z.dy0r;
for k:=1 upto (n-1):
pwl:=pwl{dp[k]}..{dp[k+1]}z.dy[k+1]l;
pwr:=z.dy[k+1]r{-dp[k+1]}..{-dp[k]}pwr;
endfor;
fill (pwl--pwr--cycle);
 enddef;

def dynpenbulb(expr pmain,phi,pl,de, dini, dfin,incuri, incurf)=
path provl,provr,res;pair vd,ovd;
z3000=point 0 of pmain; vd:=direction 0 of pmain; 
d:=angle vd+incuri; fact:=((180- abs (((d-phi-90) mod 360)-180))/180);
e:=(fact**power)
[de,pl];
penpos3000(e+dini,d-90+incuri);z3000-z3000l=(z3000-z.bi) rotated-90 scaled .5;
provl:=z3000l..{dir (d-90)}z.bi  ;
provr:=z.bi;
%dr(z3000l);dr(z3000r);dr(z.bi);


x.bi:=whatever;
y.bi:=whatever;
x[3000]:=whatever;
y[3000]:=whatever;
x[3000]l:=whatever;
y[3000]l:=whatever;
x[3000]r:=whatever;
y[3000]r:=whatever;

for k=1 upto vitesse*(( length pmain)-1):
z[3000+k]=point k/vitesse of pmain;ovd:=vd; vd:= direction k/vitesse of pmain;
d:=angle vd; 
fact:=((180- abs (((d-phi-90) mod 360)-180))/180);
e:=(fact**power)
[de,pl];
penpos[3000+k](e ,d-90);
provr:=provr..{vd}z[3000+k]r  ;
provl:=z[3000+k]l{-vd}..provl  ;
%dr(z[3000+k]l);dr(z[3000+k]r);

x[3000+k]:=whatever;
y[3000+k]:=whatever;
x[3000+k]l:=whatever;
y[3000+k]l:=whatever;
x[3000+k]r:=whatever;
y[3000+k]r:=whatever;

endfor;
z3000=point length pmain of pmain;ovd:=vd; vd:=direction length pmain   of pmain; 
d:=angle vd+incurf; fact:=((180- abs (((d-phi-90) mod 360)-180))/180);
e:=(fact**power)
[de,pl];
penpos3000(e+dfin,d-90+incurf);z3000-z3000l=(z3000-z.bf) rotated 90 scaled.5;

%dr(z3000l);dr(z3000r);dr(z.bf);

provl:=z[3000]l..provl;
provr:=provr..{dir d}z[3000]r..{dir (d+90)}z.bf;

x.bf:=whatever;
y.bf:=whatever;
x[3000]:=whatever;
y[3000]:=whatever;
x[3000]l:=whatever;
y[3000]l:=whatever;
x[3000]r:=whatever;
y[3000]r:=whatever;
 %pickup spen;
fill provl
..provr..cycle
; enddef;

def dynpen(expr pmain,phi,pl,de)=
path provl,provr,res;pair vd,ovd;
z3000=point 0 of pmain; vd:=direction 0 of pmain; 
d:=angle vd; fact:=((180- abs (((d-phi-90) mod 360)-180))/180);
e:=(fact**power)
[de,pl];
penpos3000(e,d-90);
provl:=z3000l  ;
provr:=z3000r  ;
x[3000]:=whatever;
y[3000]:=whatever;
x[3000]l:=whatever;
y[3000]l:=whatever;
x[3000]r:=whatever;
y[3000]r:=whatever;

for k=1 upto (vitesse* (length pmain)):
z[3000+k]=point (k/vitesse) of pmain;ovd:=vd; vd:= direction (k/vitesse) of pmain;
d:=angle vd; 
fact:=((180- abs (((d-phi-90) mod 360)-180))/180);
e:=(fact**power)
[de,pl];
penpos[3000+k](e ,d-90);
provr:=provr{ovd}..{vd}z[3000+k]r  ;
provl:=z[3000+k]l{-vd}..{-ovd}provl  ;
x[3000+k]:=whatever;
y[3000+k]:=whatever;
x[3000+k]l:=whatever;
y[3000+k]l:=whatever;
x[3000+k]r:=whatever;
y[3000+k]r:=whatever;

endfor;
fill provl
--provr--cycle
; enddef;



def dypm(expr p,fa,fb)=
dynpen(p,angledyn,fa*plein,fb*delie);
enddef;


def dyp(expr p)=
dypm(p,fgras,fdel);
enddef;

def dyb(expr p)=
dynpenbulb(p,angledyn+15,0.9plein,1.3hdel,bar,0,-30,0);
enddef;

def dybx(expr p)=
dynpenbulb(p,angledyn,plein,hdel,0,0.7plein,0,0);
enddef;








currenttransform:=identity slanted slant;



def sh(expr a)=
currenttransform:=currenttransform shifted (a,0);
enddef;

def vsh(expr a)=
currenttransform:=currenttransform shifted (0,a);
enddef;




def grid=
path qov,ov,ovv,ovvi,demiov,lhamp,ihamp,imhamp; inipar % ce qui r‚initialise les paramŠtres
z.c=(olarge/2,ohaut/2); z.n-z.c=(delh,ohaut/2); z.s-z.c=(delb,-ohaut/2); 
z.o-z.c=(-olarge/2,delg);z.iup=(0.75w,dhaut);z.ido=(.25w,0);
z.e-z.c=(olarge/2,deld);
y.ext+.5shaut=y.nr=y.n;x.nr-x.n=0.7slarge;x.nr-x.bou=slarge/3; x.ext-x.nr=3slarge;y.bou=y.n-shaut/3;y.er=y.e;x.er=x.e+.5slarge;
ov:=z.o{down}..z.s{right}..z.e{up}..z.n{left}..cycle; 
qov:=z.e{up}..z.n{left}..z.o{down}..z.s{right}..{up}(w-.7slarge,.8y.n); 
demiov:=z.n{left}..z.o{down}..z.s{right};
ovv:=z.s{right}..z.er{up}..tension 1..z.nr{left}..z.bou{down}..{dir45}z.ext;
ovvi:=z.s{right}..z.er{up}..tension 1..z.nr{left}..z.bou{down}..{dir70}z.ext-(slarge,0);
lhamp:=(0.9w,dhaut){left}..{(-.4w,-dhaut)}(5w/10,2.6dhaut/5)..{left}(.1w,0) ;
ihamp:=z.iup{left}..{(x.iup-x.ido,2(-y.iup+y.ido))}(5w/10,2.6dhaut/5)..{left}z.ido ;
imhamp:=z.iup{left}..{(x.iup-x.ido,2(-y.iup+y.ido))}(5w/10,2.6dhaut/5)..z.ido+(2slarge,2shaut) ;
z.no=point 3.5 of ov; z.so=point 0.5 of ov; z.se=point 1.5 of ov; z.ne=point 2.5 of ov; z.nne=point 2.75 of ov;
z0=(0,ohaut/2);z1-z0=(olarge,0);
z2=(olarge/2,0);z3=(olarge/2,ohaut);
z'1=(olarge,ohaut/2);x'30=x'4=x'5=x0;x30=x4=x5=x1;y'4=y4=ohaut;y'5=y5=y7=ohaut/4;
y30=y'30=-pbas;
z8=0.3[z3,z1];z88=0.3[z3,z0];z6=(1.5olarge,0);z'6=(0.5olarge,0);x7=1.8olarge;x10=x11=x12=x4;x'10=x'11=x'12=x'4; x13=x'4-.085*unit;x14=x13+1.2olarge/2;y13=y14=ohaut+shaut; z.i=(0,lihaut);z.f=(w,lihaut);
z''5=z5;y'10=y10=ihaut;y'11=y11=thaut;y'12=y12=dhaut;
z''0=z'0=z0;0.5[z101,z102]=(x3-slarge,1.35ohaut); 
z102-z101=(1.6slarge,shaut) ;
0.5[z103,z104]=(x3-slarge,1.35ohaut); 
z103-z104=(1.3slarge,-shaut) ;
z105=0.5[z101,z102];
.5[z'101,z'102]=(x3,1.35ohaut); z'102-z'101=(1.3slarge,shaut) ;
0.5[z'103,z'104]=(x3,1.35ohaut); 
z'103-z'104=(1.3slarge,-shaut) ;z'105=0.5[z'101,z'102];
x300=x3;x800=x8;x100=x0;y300-y3=y100-y0=y800-y8=evert;
enddef;

def Grid=
path ov,ovv, demiov,lhamp;z.c=(olarge/2,ohaut/2); z.n-z.c=(delh,ohaut/2); z.s-z.c=(delb,-ohaut/2); 
z.o-z.c=(-olarge/2,delg);
z.e-z.c=(olarge/2,deld);
y.ext=y.nr=y.n;x.nr-x.n=0.7slarge;x.nr-x.bou=slarge/3;x.ext-x.nr=2slarge;y.bou=y.n-shaut/3;y.er=y.e;x.er=x.e+.5slarge;
ov:=z.o{down}..z.s{right}..z.e{up}..z.n{left}..cycle; 
demiov:=z.n{left}..z.o{down}..z.s{right};
ovv:=z.s{right}..z.er{up}..tension 1..z.nr{left}..z.bou{down}..{dir45}z.ext;
lhamp:=(w/2,dhaut){left}..{down}(3.3w/10,3dhaut/5)..{left}(w/10,0) ;
z.no=point 3.5 of ov; z.so=point 0.5 of ov; z.se=point 1.5 of ov; z.ne=point 2.5 of ov; z.nne=point 2.75 of ov;
z0=(0,ohaut/2);z1-z0=(olarge,0);
z2=(olarge/2,0);z3=(olarge/2,ohaut);
z'1=(olarge,ohaut/2);x'30=x'4=x'5=x0;x30=x4=x5=x1;y'4=y4=ohaut;y'5=y5=y7=ohaut/4;
y30=y'30=-pbas;
z8=0.3[z3,z1];z88=0.3[z3,z0];z6=(1.5olarge,0);z'6=(0.5olarge,0);x7=1.8olarge;x10=x11=x12=x4;x'10=x'11=x'12=x'4; x13=x'4-.085*unit;x14=x13+1.2olarge/2;y13=y14=ohaut+shaut; z.i=(0,lihaut);z.f=(w,lihaut);
z''5=z5;y'10=y10=ihaut;y'11=y11=thaut;y'12=y12=dhaut;
z''0=z'0=z0;0.5[z101,z102]=(x3-slarge,1.35ohaut); 
z102-z101=(1.3slarge,shaut) ;
0.5[z103,z104]=(x3-slarge,1.35ohaut); 
z103-z104=(1.3slarge,-shaut) ;
z105=0.5[z101,z102];
.5[z'101,z'102]=(x3,1.35ohaut); z'102-z'101=(1.3slarge,shaut) ;
0.5[z'103,z'104]=(x3,1.35ohaut); 
z'103-z'104=(1.3slarge,-shaut) ;z'105=0.5[z'101,z'102];
x300=x3;x800=x8;x100=x0;y300-y3=y100-y0=y800-y8=evert;
enddef;



def mgrid=
z0=(0,ohaut/2);z1-z0=(olarge,0);z2=(olarge/2,0);z3-z2=(0,ohaut);z'1=(olarge,ohaut/2);x'30=x'4=x'5=x0;x30=x4=x5=x1;y'4=y4=ohaut;y'5=y5=y7=ohaut/4;y30=y'30=-pbas;z8=0.3[z3,z1];z88=0.3[z3,z0];z6=(1.5olarge,0);z'6=(0.5olarge,0);x7=1.8olarge;x10=x11=x12=x4;x'10=x'11=x'12=x'4; x13=x'4-.085*unit;x14=x13+1.2olarge/2;y13=y14=ohaut+shaut; z''5=z5;y'10=y10=ihaut;y'11=y11=thaut;y'12=y12=dhaut;z''0=z'0=z0;0.5[z101,z102]=(x3-slarge,1.35ohaut); z102-z101=(1.3slarge,shaut/2) ;
0.5[z103,z104]=(x3-slarge,1.35ohaut); z103-z104=(1.3slarge,-shaut/2) ;
z105=0.5[z101,z102];
.5[z'101,z'102]=(x3,1.35ohaut); z'102-z'101=(1.3slarge,shaut/2) ;
0.5[z'103,z'104]=(x3,1.35ohaut); z'103-z'104=(1.3slarge,-shaut/2) ;z'105=0.5[z'101,z'102];
x300=x3;x800=x8;x100=x0;y300-y3=y100-y0=y800-y8=evert;
enddef;

def Lhamp=

%dypm((.3w,dhaut){left}..{down}(0,3.2dhaut/4)..{right}(0.5w,0.67dh%aut),0.6,1);

dyp((.3w,dhaut){left}..{down}(0,3.2dhaut/4)..{right}(0.5w,0.67dhaut));

dypm((0.5w,0.67dhaut){right}..lhamp..{up}(-slarge,shaut)..{right}(0,2shaut)..{right}(3w/4,0)..{dir liangle}z.f,0.95,1)
enddef;

def Shamp=


dyp((.3w,dhaut){left}..{down}(0,3.2dhaut/4)..{right}(0.5w,0.67dhaut));

dypm((0.5w,0.67dhaut){right}..(lhamp slanted -1/5 shifted (slarge,0))..{up}(-slarge,shaut)..{right}(-slarge/2,1.5shaut)..{down}(0,shaut)..{up}(-.7slarge,1.5shaut),0.95,1)
enddef;

def Ahamp=   
      
dyp(reverse((-slarge,shaut){up}..{right}(-slarge/2,1.5shaut)..{down}(0,shaut)..{up}(-.7slarge,1.5shaut))..{right}(slarge,0)..{dir70}(2.8w/5,dhaut/2)..{dir40}(w,dhaut));
dypm((w,dhaut){dir -110}..{down}(.7w,-0.5shaut),0.9,1);
dypm((.7w,0){up}..{left}(.3w,.55dhaut)..tension 0.9..{down}(.2w,.4dhaut)..{right}(.65w,.1dhaut)..{dir liangle}z.f,0.9,1);
enddef;

def Ashamp=   
 dshaut:=0.93dhaut;     
dyp(reverse((-slarge,shaut){up}..{right}(-slarge/2,1.5shaut)..{down}(0,shaut)..{up}(-.7slarge,1.5shaut))..{right}(slarge,0)..{dir70}(2.8w/5,dshaut/2)..{dir40}(w,dshaut));
dypm((w,dshaut){dir -110}..{down}(.7w,-0.5shaut),0.9,1);
dypm((.7w,0){up}..{left}(.3w,.55dshaut)..tension 0.9..{down}(.2w,.4dshaut)..{right}(.65w,.1dshaut)..{dir liangle}z.f,0.9,1);
enddef;

def Ihamp=

pickup mfpen; 
draw ((-.25w,3.5dhaut/4){right}..{left}(.1w,dhaut){left}..{right}(0.3w,3.5dhaut/4)..{right}(0.7w,dhaut));
dyp(ihamp..{up}(-slarge,1.5shaut)..{right}(0,3shaut))
enddef;

def Hhamp=
path trans;
trans:=(-slarge,1.5shaut){up}..{up}(.8w+3.5slarge+.1w,dhaut-shaut)..{left}(.8w+3.5slarge,dhaut);z.cc=point .5 of trans;
z.a=z.cc+(.1pt,-1.2shaut);;x.b=x.a;y.b=y.a+2.4shaut;
pickup mfpen; 
draw ((-.25w,3.5dhaut/4){right}..{left}(.1w,dhaut){left}..{right}(0.3w,3.5dhaut/4)..{right}(0.7w,dhaut));
pickup fpen; 
draw (z.a--z.b);
dyp(ihamp..{up}(-slarge,1.5shaut)..{up}(.8w+3.5slarge+.1w,dhaut-shaut)..{left}(.8w+3.5slarge,dhaut)..tension 1.5..{right}(.8w+3.5slarge,0)..{dir liangle}z.f+(3.5slarge,0));
enddef;

def Xhamp=
path trans;
trans:=(-slarge,1.5shaut){up}..{up}(.8w+slarge+.1w,dhaut-shaut)..{left}(.8w+slarge,dhaut);z.cc=point .5 of trans;
z.a=z.cc+(.1pt,-1.2shaut);;x.b=x.a;y.b=y.a+2.4shaut;
pickup mfpen; 
dyp ((-.25w,3.5dhaut/4)..(.1w,dhaut){right}..z.cc..{left}z.ido-(.5slarge,0)..{up}(-slarge,1.5shaut)..{up}(.8w+slarge+.1w,dhaut-shaut)..{left}(.8w+slarge,dhaut)..tension 1.5..{right}(.8w+slarge,0)..{dir liangle}z.f+(slarge,0));
enddef;

def Khamp=
path trans;
trans:=(-slarge,1.5shaut){up}..{up}(.8w+3.5slarge+.1w,dhaut-shaut)..{left}(.8w+3.5slarge,dhaut);z.cd=point .25 of trans;z.cc=point .5 of trans;
z.a=z.cc+(.1pt,-.3shaut);;x.b=x.a;y.b=y.a+.6shaut;
pickup mfpen; 
draw ((-.25w,3.5dhaut/4){right}..{left}(.1w,dhaut){left}..{right}(0.3w,3.5dhaut/4)..{right}(0.7w,dhaut));

dyp(ihamp..{up}(-slarge,1.5shaut)..z.cd);

dyp((.8w+3.5slarge+.1w,dhaut-shaut){up}..(.8w+3.5slarge,dhaut){left}..(.8w+2.5slarge,0.9dhaut)..{left}z.a..{right}z.b
..{right}(.8w+3.5slarge,0)..{dir liangle}z.f+(3.5slarge,0));
enddef;


def Dhamp=

dypm(ihamp..{up}(-slarge,shaut)..{right}(0,2shaut)..{right}(4w/5,0)..{up}(1.2w,dhaut/2.5),0.9,1)
dyp((1.2w,dhaut/2.5){up}..(w/3,dhaut){left}..{down}(-2slarge,.7dhaut)..{right}(w/5,.5dhaut));
enddef;

def Bhamp=

dypm(ihamp..{up}(-slarge,shaut)..{right}(-slarge/2,1.5shaut)..{down}(0,shaut)..{up}(-.7slarge,1.5shaut),0.9,1);

dyp((0.25w,shaut){dir-20}..{dir-10}(.6w,0));

dyp((.6w,0){dir-10}..(1.2w,1.7shaut){up}..(w/1.7,dhaut/1.9){left}..{down}(w/1.8,dhaut/2)..{right}(w/1.7,dhaut/2.1)..(0.85w,dhaut/1.5){up}..{left}(w/3,1.05dhaut));

dyp((w/3,1.05dhaut){left}..{down}(-2slarge,.8dhaut)..{right}(w/5,.6dhaut));
enddef;

def Rhamp=

dypm((imhamp shifted (-slarge,0))..{up}(((-slarge,shaut)..{right}(-slarge/2,1.5shaut)..{down}(0,shaut)..{up}(-.7slarge,1.5shaut))shifted(0,0.5shaut)),0.9,1);


dypm(reverse((0.85w,0){left}..(((w/1.7-.9slarge,dhaut/2.1){left}..{down}(w/1.8-.9slarge,dhaut/2.2)..{right}(w/1.7-.9slarge,dhaut/2.3))shifted (0,.5shaut))..(0.75w,dhaut/1.5){up}..{left}(w/3,1.05dhaut))..{dir lihaut}z.f,0.9,1);

dypm((w/3,1.05dhaut){left}..{down}(-2slarge,.8dhaut)..{right}(w/5,.6dhaut),0.7,1);
enddef;

def Fhamp=

dyp(imhamp..{up}(((-slarge,shaut)..{right}(-slarge/2,1.5shaut)..{down}(0,shaut)..{up}(-.7slarge,1.5shaut))shifted(0,2shaut)));
pickup fpen;
draw((w/3,dhaut/2){dir40}..{left}(2w/3,1.2dhaut/2)---{dir-75}(2w/3,0.9dhaut/2));

dyp(reverse((w/3,dhaut){left}..{down}(-2slarge,.8dhaut)..{right}(w/5,.6dhaut))..{right}(2w/3,.9dhaut)..(w,dhaut));


enddef;

def Phamp=

dyp(imhamp..{up}(((-slarge,shaut)..{right}(-slarge/2,1.5shaut)..{down}(0,shaut)..{up}(-.7slarge,1.5shaut))shifted(0,2shaut)));


dyp((w/1.7,dhaut/2.1){right}..(0.95w,dhaut/1.5){up}..{left}(w/3,1.05dhaut));

dyp((w/3,1.05dhaut){left}..{down}(-2slarge,.8dhaut)..{right}(w/5,.6dhaut));


enddef;

def agrid=
save inidelh;
inidelh:=0.3slarge;
grid;
enddef;

def Agrid=
delh:=0.3slarge;
Grid;
enddef;






def ovale =

dypm(ov,0.94,1);
enddef;


def aovale =
dypm(ov,0.94,1);
enddef;

def aqovale =
dypm(qov,0.94,1);
enddef;

def ovve =
dypm(demiov,0.94,1);dypm(ovv,0.7,1.1);
enddef;

def ovvn =
dypm(demiov,0.94,1);dypm(ovvi,0.7,1.1);
enddef;

def queue=
x.q0=x0-slarge;y.q0=lihaut;z.q1=z88+(-0.6slarge,0); pickup spen; draw z.q0{dir liangle}..{dir75}z.q1;
enddef;

def equeue=
x.q0=x'0-0.8shaut; y.q0=lihaut;pickup ffpen; draw z.q0{dir 55}..{dir75}z'0;
enddef;


def enne=
x66=x6-slarge/3;x77=x7-2slarge/3; y66=y6;y77=lihaut;z40=(0,0);
dyp(z40{up}..z.n{right}..z'1..z66..{dir liangle}z.f-(slarge,0));
enddef;

def penne=
x66=x6-slarge/3;x77=x7-2slarge/3; y66=y6;y77=lihaut;z40=(0,0);
dyp(z40{up}..z.n{right}..z'1..z66..{dir liangle}(z.f-(slarge,0)));
enddef;

def ekke=
x66=x6-slarge/3;x77=x7-2slarge/3; z''8=z8+(0.2olarge,0);y66=y6;y77=lihaut;z40=(0,0);x'''1=olarge/4;y'''1=y'1;z'''1=z'''2;
dyp( z40{up}..z.n..z''8+(.5slarge,0)..z'''1);
dyp(z'''2..z5..z66..{dir liangle}z.f);
enddef;

def evve=
z'881=z'88+(3slarge,0);z'88=z88+(olarge,0);z91-z'1=z93-z3=z92-z2=(olarge,0);path ppr; pair direc,diref;ppr=z88..z3..z'1..z5..z92..z91..z93..z'88.. tension 3..z'881; direc=direction 6.5 of ppr;z.pa=point 6.5 of ppr ;diref=direction 8 of ppr ;
dyp((z.i+(1.1slarge,0){up}..z88..z3..z'1..z5..z92..z91..z93..{direc}z.pa) shifted (0.4slarge,0)); pickup fpen; draw (z.pa{direc}..tension 2..{diref}z'881) shifted (0.4slarge,0);
enddef;

def nvbarre=
z'881=z'88+(3slarge,0);z'88=z88+(0,0);z91-z'1=z93-z3=z92-z2=(0,0);

dyp((z.i+(1.1slarge,0){up}..z88..z3..z'1..(x'1,0)) shifted (0.4slarge,0)); 
enddef;
def erasenb=
pickup llpen; undraw (x.i+1.1slarge,0)--(x.i+1.1slarge,y.ext);
enddef;

def ewe=
z'881=z'88+(3slarge,0);z'88=z88+(olarge,0);z91-z'1=z93-z3=z92-z2=(olarge,0);path ppr; pair direc,diref;ppr=z88..z3..z'1..z5..z92..z91..z93..z'88.. tension 3..z'881; direc=direction 6.5 of ppr;z.pa=point 6.5 of ppr ;diref=direction 8 of ppr ;
dyp
(
(
z.i+(1.1slarge,0){up}..z88..z3..z'1..z5..{right}z92..{up}
(z'4 slanted -1/6 shifted (z92-z'6+(olarge,0)))
)
shifted(1.7slarge-olarge,0)
);
dyp((z92-(.5slarge,0){right}..z91..z93..{direc}z.pa)shifted(1.5slarge,0));  dypm((z.pa{direc}..tension 2..{diref}z'881)shifted(1.5slarge,0),0.4,1) ;
dypm((((z'4--z''0--z'5) slanted -1/6)..{dir10}z'6)shifted (z92-z'6+(1.7slarge,0)),0.85,0);

enddef;

def erre=
z80=(0,0);
dyp(z8..z3..{down}z80);dyp(z80{up}..z3..z8);
enddef;

def esse=
z83=z8+(slarge/1.5,-shaut/3);
z80+z83=(olarge,ohaut);x81=x83;x82=x80;y81=y80;y82=y83;
z99-(0,shaut/4)=0.5[z80,z8];
dyp(z83..z3..z82..z99..z81..z2..z80);
enddef;

def essvar=
z83=z8+(slarge/1.5,-shaut/3);
z80+z83=(olarge,ohaut);x81=x83+.5slarge;x82=x80;y81=y80;y82=y83;x800:=x80;y800:=lihaut;
z99-(0,shaut/4)=0.5[z80,z8];z''3=z3+(0,shaut/3);angledyn:=75;fgras:=0.87fgras;
dyp(z''3{down}..{down}z81..z2+(slarge,-.15shaut)..{up}(z80+(slarge,-.15shaut)));
fgras:=fgras/0.87;
angledyn:=-20;
dyp(z80+(slarge,-.15shaut){up}..tension1.5..{dir liangle}z.f); 
%pickup mpen; drawdot z80-(0,0.3shaut); 
pickup fpen; draw z.i{dir liangle}..z3;
enddef;

def essovar=
z83=z8+(slarge/1.5,-shaut/3);
z80+z83=(olarge,ohaut);x81=x83+.5slarge;x82=x80;y81=y80;y82=y83;x800:=x80;y800:=lihaut;
z99-(0,shaut/4)=0.5[z80,z8];z''3=z3+(-.7slarge,shaut/3);
angledyn:=75;
fgras:=0.77fgras;
dyp(z''3{down}..{down}z81..z2+(slarge,-.15shaut)..{up}(z80+(slarge,-.15shaut)));
fgras:=fgras/0.77;
angledyn:=-20;
dyp(z80+(slarge,-.15shaut){up}..tension1.5..{dir liangle}z.f);
%pickup mpen; drawdot z80-(0,0.3shaut); 
enddef;



def zed=
x3:=x'1+.5slarge;y3:=y'4;
x66=x6-2slarge/3;x77=x7-2slarge/3; y66=y6;y77=y7;z40=(0,0);
z.in=z0-(0.18slarge,1.31shaut); penpos'4(0.5slarge,-10);
z150+z100=2z0=z350+z300=z850+z800;z'100=(0,0);z'''5=z5+(olarge-slarge,ohaut/4);z90-z0=z'150-z150=(olarge,0);z'350-z350=z'850-z850=(olarge-2slarge,0);z''100-z'100=(olarge-slarge,0);

dyp(z.i{dir liangle}..z'4r+(0,0.3shaut){up}..z'4l+(0,0.3shaut){(x3,-y3/2)}..{(x3,y3/2)}z3)
pickup fpen ;
draw z3--(1.5slarge,0);
dypm((1.5slarge,0){(x3,.4y3)}..((%z'1+(0,-3shaut)..
z'150..z'350..z'850..tension4..{dir liangle}z.f)shifted (1.5slarge,0)),0.9,1);
enddef;

def ozed=
x3:=x'1+.5slarge;y3:=y'4;
x66=x6-2slarge/3;x77=x7-2slarge/3; y66=y6;y77=y7;z40=(0,0);
z.in=z0-(0.18slarge,1.31shaut); penpos'4(0.5slarge,-10);
z150+z100=2z0=z350+z300=z850+z800;z'100=(0,0);z'''5=z5+(olarge-slarge,ohaut/4);z90-z0=z'150-z150=(olarge,0);z'350-z350=z'850-z850=(olarge-2slarge,0);z''100-z'100=(olarge-slarge,0);

dyp(z'4r-(0,0.3shaut)..z'4r+(0,0.3shaut){up}..z'4l+(0,0.3shaut){(x3,-y3/2)}..{(x3,y3/2)}z3);
pickup fpen ;
draw z3--(1.5slarge,0);

dypm((1.5slarge,0){(x3,.5y3)}..((z'1+(0,-2shaut){z'150-z'1}..z'150..z'350..z'850..tension4..{dir liangle}z.f)shifted(1.5slarge,0)),0.9,1);
enddef;

def emme=
x'66-olarge=x66=x6-2slarge/3;x'77-olarge=x77=x7-2slarge/3; y'66=y66=y6;y'77:=lihaut;y77=y7;z'40-(olarge,0)=z40=(0,0);x55=x5;y55=0;
z43-(olarge,0)=z3;z41-(olarge,0)=z'1;z45-(olarge,0)=z5;
dyp(z40{up}..z3..z'1..z5..z55);
dyp(z'40{up}..z43..z41..z45..z'66..{dir liangle}z.f-(.5slarge,0));
enddef;

def serif=
z''4=z'4-(0.2olarge,0);pickup fpen; draw z''4--z'4;
enddef;

def oserif=
x81+x''8=2x1;y81=y''8=y8+shaut/2;x''8-x1=(x1-x8)/1.5;
pickup ffpen;
 draw z81{dir-25}..{dir25}z''8;
enddef;

def phampe=
dyp( z'4--z'30);
enddef;

def qhampe=
dyp( z4--z30);
enddef;

def oevale=
dypm(ov xscaled 2/3,0.9,1);
dypm(((z.o{dir 15}..z8-(0,0.5shaut)..z.o..z.s)xscaled 2/3 shifted(w/2.2,0))..{dir liangle}z.f,0.9,1);
enddef;

def eboucle=
%x'.se=1.4[x.s,x.se];y'.se=lihaut;
dypm(z.o{dir 15}..z8..z.o..z.s..{dir liangle}z.f,0.94,1);
enddef;

def evboucle=
%x'.se=1.4[x.s,x.se];y'.se=lihaut;
dypm(z.o{dir 15}..z8..z.o..z.s..{up}z.f-(.7slarge,0),0.96,1);
enddef;


def lboucle=
dypm(z.i{dir liangle}..tension2 ..z800..z300..z100..tension2..z0..z2..{dir liangle}z.f,0.94,1);enddef;

def lbboucle=
dypm(z.i+(slarge,2.9shaut){dir 50}..tension3 ..z800..z300..z100..tension2..z0..z2..{dir liangle}z.f,0.94,1);enddef;


def lserif=
z''2=z2;x'1000:=x'1000+0.3olarge;
penpos1001(bar,180);penpos'1000(midel,75);penpos1(plein,180);penpos2(plein,0);penpos''2(plein,180);penpos5(delie,180);pickup mpen1;
draw z'1000{dir -50}..tension1..z800;
draw z1001{up}..tension1.5..{right}z2..z5;
enddef;

def iserif=
x'1000=-1.6/1.2olarge;x1001:=1.2x'1000;x1003=x'1000+slarge;y'1000-2shaut=y800=y1003;z''2=z2;z'''0=z0;z'300=z''300=z300-(0.3olarge,0);
penpos1003(2delie,-15);penpos1001(2delie,180);
penpos'1000(delie,180);
penpos'''0(0,90);penpos1(plein,180);penpos2(plein,0);penpos''2(plein,180);penpos5(delie,180);penpos''300(1.2delie,135);penpos'300(1.6delie,270);
pickup fpen;
draw z1003{dir75}..{down}z'1000{down}..tension2..{dir75}z''300;
draw z1002{dir 195}..{up}z1001..tension2..z'''0;
enddef;

def fboucle=
z150+z100=2z0=z350+z300=z850+z800;z'100=(0,0);x'''5=x5;x.f1=x'0-.3slarge;y.f1=lihaut=y'''5;
dypm(z.f1{dir liangle}..tension2 ..z800..z300..z100..z0..z150..z350..z850..tension2..z'100..{dir liangle}z.f,0.9,1);
enddef;


def jboucle=
z150+z100=2z0=z350+z300=z850+z800;z'100=(0,0);z'''5=z5+(olarge,ohaut/4);z90-z0=z'150-z150=z'350-z350=(z'850-z850)=z''100-z'100=(olarge,0);
dypm( z4..z'1..z'150..z'350..z'850..tension2..z.f+(slarge,0),0.9,1);
enddef;

def iqueue=
pickup fpen; draw (z.i{dir liangle}..z'4+(.7slarge,0));
enddef;

def uqueue=
2z99=z0+z1-(2olarge,0);
pickup fpen; draw (z99{dir liangle}..z'4);
enddef;

def jqueue=
pickup fpen; draw (z.i+(1.4slarge,0){dir liangle}..z4) ;
enddef;

def gboucle=
z150+z100=2z0=z350+z300=z850+z800;z'100=(0,0);z'''5=z5+(olarge-slarge,ohaut/4);z90-z0=z'150-z150=(olarge,0);z'350-z350=z'850-z850=(olarge-2slarge,0);z''100-z'100=(olarge-slarge,0);
dypm(z4..z'1..z'150..z'350..z'850..tension4..{dir liangle}z.f,0.9,1);%z''100
enddef;

def Jboucle=
z150+z100=2z0=z350+z300=z850+z800;z'100=(0,0);z'''5=z5+(olarge-slarge,ohaut/4);z90-z0=z'150-z150=(olarge,0);z'350-z350=z'850-z850=(olarge-2slarge,0);z''100-z'100=(olarge-slarge,0);
pickup mfpen; 
draw ((-.15w,3.5dhaut/4){right}..{left}(.1w,dhaut){left}..{right}(0.3w,3.5dhaut/4)..{dir30}(0.7w,dhaut));

dyp(z.iup{dir240}..z'1+(slarge,0)..z'150..z'350..z'850..tension4..{dir liangle}z.f);%z''100
enddef;




def cnboucle= 
x.cbo-x.se=1/6(x.se-x.s);
y.cbo-y.se=1/3(y.se-y.s);
dyp(z.nne..z.n..z.o..z.s..z.se..{dir liangle}z.f);pickup lpen; drawdot z.nne;
enddef;

def cboucle= 
x.cbo-x.se=1/6(x.se-x.s);
y.cbo-y.se=1/3(y.se-y.s);
fgras:=1.2fgras;
dyb(z.nne..z.n..z.o..z.s..z.se..{dir liangle}z.f);fgras:=fgras/1.2;
%pickup lpen; drawdot z.nne;
enddef;

def clboucle= 
x.cbo-x.se=1/6(x.se-x.s);
y.cbo-y.se=1/3(y.se-y.s);
fgras:=1.2fgras;pickup fpen; draw (z.s shifted (-.2slarge,0){right}..{dir liangle}z.f);
dyb(((z.nne..z.n..z.o..{right}z.s)shifted (-.2slarge,0)));fgras:=fgras/1.2;
%pickup lpen; drawdot z.nne;
enddef;

def cxboucle= 
x.cbo-x.se=1/6(x.se-x.s)+slarge;
y.cbo=y.f;fdel:=1.5fdel;
dyb(z.nne..z.n..z.o..z.s{right}..{dir liangle}z.cbo);
fdel:=fdel/1.5;pickup fpen;
draw z.s{right}..{dir liangle}z.cbo;
%pickup lpen; drawdot z.nne;
enddef;


def Eboucle=
z'99=z99=z0+(olarge/3,shaut);
dyp( z99..z3..z8);
dyp( z'99..z2..{dir liangle}z.f);pickup lpen; drawdot z8
enddef;

def xboucle=
z'400+z'0=z400+z.o=z401+z1=z402+z.s=z408+z.nne=z405+z.se=z403+z3=2z.o+ (0,.5shaut);
dypm((x405-slarge,y.i){dir liangle}..z405..z402..z400..z403..z408,0.85,1);
pickup lpen; drawdot z408;
enddef;

def oxboucle=
z'400+z'0=z400+z.o=z401+z1=z402+z.s=z408+z.nne=z405+z.se=z403+z3=2z.o+ (0,.5shaut);
dypm(z405..z402..z400..z403..z408,0.85,1);
pickup lpen; drawdot z408;
enddef;



def abarre=
dyp( z4--z'1--z5..z6..{dir liangle}z.f);
enddef;

def avbarre=
dyp( z4--z'1--z5..z6..{up}z.f-(.7slarge,0));
enddef;

def nbarre=
z20=(0,0);dyp( z'4--z20);
enddef;

def bbarre=
dypm(z.i{dir liangle}..tension2 ..z800..z300..z100..tension2..z0..{right}z.s,0.94,1);
dypm(ovv,0.8,1);enddef;

def bbbarre=
dypm(z.i+(0.9slarge,2.8shaut){dir 50}..tension3 ..z800..z300..z100..tension2..z0..{right}z.s,0.94,1);
dypm(ovv,0.8,1);enddef;


def hbarre=
x.l=x'0-shaut; y.l=y.l1=lihaut; x.l1=x5;x1800=x800+slarge;y1800=y800;z301=z300+(0.1olarge,0);z'1000=z'0+(0.1olarge,0);z1001=z100+(0.1olarge,0);
z80=(0.1olarge,0);z20=(0.1olarge,ohaut);z200=(0.05olarge,dhaut+shaut);
dypm(z.i{dir liangle}..tension2..z1800..z301..z1001..z20---z80,0.94,1);
enddef;

def errevar=
x66=x6-2slarge/3;x77=x7-2slarge/3; y66=y6;y77=y7;z40=(0,0);
z.in=z0-(0.18slarge,1.31shaut); penpos'4(0.5slarge,-10);
dyp(z.i{dir liangle}..z'4r+(0,0.3shaut)..z'4l+(0,0.3shaut)..z3-(0,0.3shaut)..z'1+(0,shaut)..z5..z66..{dir liangle}z.f);

enddef;

def errevor=
x66=x6-2slarge/3;x77=x7-2slarge/3; y66=y6;y77=y7;z40=(0,0);
z.in=z0-(0.18slarge,1.31shaut); penpos'4(0.5slarge,-10);
dyp(z'4r-(0,0.3shaut)..z'4r+(0,0.3shaut)..z'4l+(0,0.3shaut)..z3-(0,0.3shaut)..z'1+(0,shaut)..z5..z66..{dir liangle}z.f);

enddef;

def ibarre=
dyp( z'4--z''0--z'5..z'6..{dir liangle}z.f-(0.7slarge,0));
enddef;

def iibarre=
dyp( z'4--z''0--z'5..z'6..{dir liangle}z.f-(slarge,0));
enddef;

def ivbarre=
dyp( z'4--z''0--z'5..z'6..{up}z.f-(1.4slarge,0));
enddef;

def iobarre=
dyp( z'4--z''0--z'5..z'6..z''5);
enddef;


def tbarre=
dyp(z'11+(0,+.7shaut)--z''0--z'5..z'6..{dir liangle}z.f);
enddef;

def dbarre=
dyp(z12-(0,shaut)--z'1--z5..z6..{dir liangle}z.f);
enddef;

def thbarre=
pickup mfpen; draw ((z13-(.6slarge,0)--z14+(.7slarge,0))shifted(0,0.7shaut))  ;
enddef;

def ipoint=
 pickup lpen;drawdot z'10;
enddef;

def jpoint=
 pickup lpen;drawdot z'10+(olarge,0);
enddef;

def aigu=
dypm(z102{down}..z101,0.9,1);
enddef;

def grave=
x103:=x103+1pt;x104:=x104-1pt;
dypm(z103{left}..z104,0.85,1);
enddef;

def Grave=
x103:=x103+1pt;x104:=x104-1pt;
dyp(z104{dir-40}..z103);
enddef;
def agrave=
x'103:=x'103+1pt;x'104:=x'104-1pt;
dypm(z'103{left}..z'104,0.85,1);
enddef;

def cflex=
z201-z1001=z205-z105=z203-z1003=(0.05*unit,0);
z1001=2[z105,z101];z1003=2[z105,z103];
dyp( z203--z205--z201);
enddef;

def tilde=
z201-z1001=z205-z105=z203-z1003=(0.05*unit,0);
z1001=2[z105,z101];z1003=2[z105,z103];
dyp(z201+(-.7slarge,0.8shaut){dir60}..{dir60}z203+(.7slarge,1.2shaut));
enddef;

def oflex=
z201-z1001=z205-z105=z203-z1003=(0.25*unit,0);
z1001=2[z105,z101];z1003=2[z105,z103];
dyp(z203--z205--z201);
enddef;


def aflex=
z'1001=2[z'105,z'101];z'1003=2[z'105,z'103];
dyp(z'1003--z'105--z'1001);
enddef;

def iflex=
z'1001=2[z'105,z'101];z'1003=2[z'105,z'103];z201-z'1001=z205-z'105=z203-z'1003=(-slarge,0);
dyp(z203--z205--z201);
enddef;

def cedille=
z400=z2;x401=x402=x2;y401=-shaut/2;y402=-3shaut/2;y403=-shaut;x403=x2+slarge;dyp((z400--z401..z403..z402)shifted (-0.5slarge,0));
enddef;

def Cedille=
z400=z2;x401=x402=x2;y401=-1.5shaut/2;y402=-5shaut/2;y403=-1.5shaut;x403=x2+slarge;dyp((z400--z401..z403..z402)shifted (-0.5slarge,0));
enddef;

def itrema=
 pickup lpen;drawdot z'10-(olarge/6,0);
 drawdot z'10+(olarge/3,0);
enddef;

def trema=
 pickup lpen;drawdot z'10;
 drawdot z'10+(olarge,0);
enddef;

def etrema=
 pickup lpen;drawdot z'10+(-0.05olarge,0);
 drawdot z'10+(0.45olarge,0);
enddef;


%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% d‚but des caractŠres...

currenttransform:=identity slanted 3/5 slant;

beginchar ("L",1.35wm,2wm,0pt#);grid;
Lhamp;charwd:=charwd-slarge#-0.3pt#;w:=w-slarge-0.3pt;endchar;

beginchar ("S",1.35wm,2wm,0pt#);grid;
Shamp;charwd:=charwd-2slarge#-1.5pt#;w:=w-2slarge-1.5pt;endchar;

beginchar ("Z",1.5wm,2wm,0pt#);grid;

dyp((0,0.8dhaut)..{left}(0,dhaut+slarge)..{right}(w/5,dhaut-.3shaut)..{(0.8w,dhaut+shaut)}(0.8w,dhaut+shaut));pickup mfpen
dypm( (0.8w,dhaut+shaut)..{dir240}(0,0),0.9,1); draw (1.7w/5,4/7dhaut)--(2.9w/5,4/7dhaut);
dyp((0,0){dir60}..(w/5,shaut)..(3w/5,0)..{dir liangle}z.f);
endchar;


beginchar ("A",1.35wm,2wm,0pt#);grid;
Ahamp;charwd:=charwd-1.2pt#;w:=w-1.2pt;endchar;

beginchar (192,1.35wm,2wm,0pt#);grid;
Ashamp;sh(w-x103+1.5slarge);vsh(1.13dhaut-y103-shaut); Grave;vsh(-1.13dhaut+y103+shaut);sh(-w+x103-1.5slarge);charwd:=charwd-1.2pt#;w:=w-1.2pt;endchar;%%%%%%%% "…" majuscule

beginchar (194,1.35wm,2wm,0pt#);grid;
Ashamp;sh(w-x103+1.5slarge);vsh(1.16dhaut-y103-shaut); cflex ;vsh(-1.16dhaut+y103+shaut);sh(-w+x103-1.5slarge);charwd:=charwd-1.2pt#;w:=w-1.2pt;endchar;%%%%%%%% "ƒ" majuscule


currenttransform:=identity slanted slant;

beginchar ("H",1.15wm,2wm,0pt#);grid;
Hhamp;charwd:=charwd-1.5pt#+3.5slarge#;w:=w-1.5pt+3.5slarge;
endchar;

beginchar ("X",1.15wm,2wm,0pt#);grid;
Xhamp;charwd:=charwd-1.5pt#+slarge#;w:=w-1.5pt+slarge;
endchar;


beginchar ("I",1.15wm,2wm,0pt#);grid;
Ihamp;charwd:=charwd-2.85pt#;w:=w-2.85pt;
endchar;

beginchar ("J",1.15wm,2wm,wm);grid;
Jboucle;charwd:=charwd-1.2pt#;w:=w-1.2pt;
endchar;

beginchar ("K",1.15wm,2wm,0pt#);grid;
Khamp;charwd:=charwd-1.5pt#+3.5slarge#;w:=w-1.5pt+3.5slarge;
endchar;


beginchar ("D",1.15wm,2wm,0pt#);grid;
Dhamp;charwd:=charwd+2.2slarge#;w:=w+2.2slarge;
endchar;

beginchar ("O",1.15wm,2wm,0pt#);grid;

dyp((w/2,dhaut){left}..(0,4dhaut/7)..(w/2,0)..{up}(w,dhaut/2));
pickup mfpen;
draw ((w,dhaut/2){up}..(w/2,0.93dhaut)..(w/4,5dhaut/7));
endchar;

beginchar (212,1.15wm,2wm,0pt#);grid;

dyp((w/2,dhaut){left}..(0,4dhaut/7)..(w/2,0)..{up}(w,dhaut/2));
pickup mfpen;
draw ((w,dhaut/2){up}..(w/2,0.93dhaut)..(w/4,5dhaut/7));
sh(4.6slarge);vsh(1.16dhaut-y103);cflex;vsh(-1.16dhaut+y103);sh(-4.6slarge);
endchar; %%%%%%%%%%% “ majuscule


beginchar ("Q",1.15wm,2wm,wm);grid;

dyp((w/2,dhaut){left}..(0,4dhaut/7)..(w/2,0)..(w,dhaut/2)..{left}(w/2,0.85dhaut));
dypm ((w/2,0.85dhaut){left}..(w/4,0.6dhaut){down}..(1.1w,-1.5shaut)..(.9w,-pbas+shaut),0.9,1);
endchar;

beginchar ("F",1.15wm,2wm,0pt#);grid;
Fhamp;charwd:=charwd;w:=w;
endchar;

beginchar ("P",1.15wm,2wm,0pt#);grid;
Phamp;charwd:=charwd-2pt#;w:=w-2pt;
endchar;

beginchar ("B",1.15wm,2wm,0pt#);grid;
Bhamp;charwd:=charwd+2.2slarge#;w:=w+2.2slarge;
endchar;

beginchar ("R",1.15wm+2.2slarge#,2wm,0pt#);grid;
Rhamp;charwd:=charwd-1.5pt#;w:=-1.5pt;
;
endchar;

beginchar ("M",2wm,2wm,0pt#);grid;
sh(w/5);
dyp((-w/5,2shaut)..{right}(0,0)..tension 1.5..{up}(3w/25,3dhaut/5)..tension 1.5..{right}(1.3w/5,dhaut));
dyp((1.3w/5,dhaut){down}..tension1.5..{right}(2.1w/5,0));
dyp((2.1w/5,0){up}..tension1.5..{right}(3w/5,dhaut))
dyp((3w/5,dhaut){down}..(4w/5,0)..{dir liangle}z.f);sh(-w/5);charwd:=charwd+2/5wm-1.2pt#;w:=6w/5-1.2pt;
;endchar;

beginchar ("U",2wm,2wm,0pt#);grid;
sh(w/5);
dyp((0,3dhaut/5){left}..{up}(-w/5,4dhaut/5)..(0.3w/5,dhaut){right}..tension1.5..{right}(1.6w/5,0)..tension1.5..{up}(3w/5,dhaut))
dyp((3w/5,dhaut){down}..(4w/5,0)..{up}z.f);sh(-w/5);charwd:=charwd+2/5wm-1.2pt#;w:=6w/5-1.2pt;
;endchar;




beginchar ("V",2wm,2wm,0pt#);grid;
sh(w/5);
dyp((0,3.6dhaut/5)..{up}(-w/5,4dhaut/5)..{dir 70}(0.3w/5,dhaut));

dyp((0.3w/5,dhaut){down}..tension1.5..{down}(1w/5,0)..{left}(1w/5-.1slarge,-.3shaut)..{up}(1w/5-.2slarge,0)..tension1.5..{left}(3w/5,dhaut)..(3.5w/5,4.5dhaut/5)..{right}(1.2w,dhaut));sh(-w/5);charwd:=charwd+2/5wm-1.2pt#;w:=6w/5-1.2pt;
;endchar;

beginchar ("W",2wm,2wm,0pt#);grid;
sh(w/5);
dyp((0,3.6dhaut/5)..{up}(-w/5,4dhaut/5)..{dir 70}(0.3w/5,dhaut));

dyp((0.3w/5,dhaut){down}..tension1.5..{down}(1w/5,0)..{left}(1w/5-.1slarge,-.3shaut)..{up}(1w/5-.2slarge,0)..tension1.5..{up}(1.9w/5,dhaut));


dyp((1.9w/5,dhaut){down}..tension1.5..{down}(2.6w/5,0)..{left}(2.6w/5-.1slarge,-.3shaut)..{up}(2.6w/5-.2slarge,0)..{left}(3w/5,dhaut)..(3.5w/5,4.5dhaut/5)..{right}(1.1w,dhaut));sh(-w/5);charwd:=charwd+2/5wm-1.2pt#;w:=6w/5-1.2pt;
;endchar;

beginchar ("N",1.4wm,2wm,0pt#);grid;
sh(w/3);
dyp((-w/3,2shaut)..{right}(0,0)..tension 1.5..{up}(1.4w/5,dhaut));
dyp((1.4w/5,dhaut){down}..tension1.5..{down}(3w/5,0));
dyp((3w/5,0){up}..tension1.5..{right}(4w/5,dhaut)..(w,4dhaut/5))
;sh(-w/5);charwd:=charwd+1.4/3wm-1pt#;w:=4w/3-1pt;
endchar;

%%%%%%%%%%%%%%%% Majuscules "bƒtons" %%%%%%%%%%%%%%%




beginchar (160,1.2wm,wm,0pt#);grid;
dypm((w/2,dphaut+.5shaut)--(slarge,-.5shaut),0.9,1);
dypm((w/2,dphaut)--(w-slarge,-.5shaut),0.9,1);pickup lpen;
draw((.8w/3,2.5/5dphaut)--(3w/4,2.5/5dphaut));
endchar;%%% "A"

beginchar (161,1.2wm,wm,0pt#);grid;
dypm((1.5slarge,dphaut)--(slarge,0),0.9,1);
dypm(((.5slarge,dphaut){right}..{left}(slarge,4/7dphaut))xscaled 1.5,0.9,1);
dypm(((slarge,4/7dphaut){right}..{dir170}(.2slarge,0))xscaled 1.5,0.9,1);
endchar;%%% "B"

beginchar (162,wm,wm,0pt#);grid;sh(-.7slarge);
dyp((w-1.5slarge,dphaut){left}..{down}(.5slarge,4/7dphaut)..{right}(w-.5slarge,0));sh(.7slarge);
endchar;%%% "C"

beginchar (163,1.2wm,wm,0pt#);grid;
dypm((1.5slarge,dphaut)--(slarge,0),0.9,1);
dypm(((.5slarge,dphaut){right}..{dir170}(.2slarge,0))xscaled 1.1,0.9,1);
endchar;%%% "D"

beginchar (164,1.wm,wm,0pt#);grid;
dypm((1.5slarge,dphaut)--(slarge,0),0.9,1);
pickup lspen;
draw((1slarge,dphaut)--(w-slarge,dphaut));
draw((1slarge,0)--(w-slarge,0));

draw((1slarge,4/7dphaut)--(2w/3,4/7dphaut));
endchar;%%% "E"


%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar (165,1.wm,wm,0pt#);grid;
dypm((1.5slarge,dphaut)--(slarge,-.5shaut),0.9,1);
pickup lspen;
draw((slarge,dphaut)--(w-slarge,dphaut));

draw((slarge,4/7dphaut)--(2w/3,4/7dphaut));
endchar;%%% "F"

beginchar (166,1.1wm,wm,0pt#);grid;
dyp((w-1.5slarge,dphaut){left}..{down}(.5slarge,4/7dphaut)
..{right}(w/2,0)..{up}(w-slarge,3/7dphaut));
pickup lpen;
draw((w/2,3/7dphaut)--(w-slarge,3/7dphaut));

endchar;%%% "G"

beginchar (167,1.wm,wm,0pt#);grid;
dypm((slarge,dphaut)--(slarge,-.5shaut),0.9,1);
dypm((w-slarge,dphaut)--(w-slarge,-.5shaut),0.9,1);
pickup lpen;
draw((slarge,4/7dphaut)--(w-slarge,4/7dphaut));

endchar;%%% "H"

beginchar (168,0.7wm,wm,0pt#);grid;
dypm((w/2,dphaut)--(w/2,-.5shaut),0.9,1);
pickup lpen;
drawdot((w/2,6/5dphaut));

endchar;%%% "I"

beginchar (169,wm,wm,0pt#);grid;
dypm((w-slarge,dphaut){down}...{left}(3w/5,0)..(slarge,dphaut/4),0.9,1);
pickup lpen;
drawdot((w-slarge,6/5dphaut));
endchar;%%% "J"

beginchar (170,1.2wm,wm,0pt#);grid;
dypm((slarge,dphaut)--(slarge,-.5shaut),0.9,1);
dypm((w-2slarge,dphaut)--(1.5slarge,4/7dphaut-.5shaut),0.9,1);
dypm((slarge,4/7dphaut)--(w-slarge,-.5shaut),0.9,1);

endchar;%%% "K"

%%%%%%%%%%%%%%%% Accents %%%%%%%%%%%%%%%


beginchar (171,1.wm,wm,0pt#);grid;
dypm((1.5slarge,dphaut)--(slarge,0),0.9,1);
pickup lspen;
draw((1slarge,0)--(w-slarge,0));

endchar;%%% "L"

beginchar (172,1.2wm,wm,0pt#);grid;
dypm((slarge,dphaut)--(slarge,-.5shaut),0.9,1);
dypm((w-slarge,dphaut)--(w-slarge,-.5shaut),0.9,1);
dypm((slarge,dphaut)--(w/2,4/7dphaut),0.9,1);
dypm((w-slarge,dphaut)--(w/2,4/7dphaut),0.85,1);

endchar;%%% "M"

beginchar (173,1.2wm,wm,0pt#);grid;
dypm((slarge,dphaut)--(slarge,-.5shaut),0.9,1);
dypm((w-slarge,dphaut)--(w-slarge,-.5shaut),0.9,1);
dypm((slarge,dphaut)--(w-slarge,0),0.9,1);

endchar;%%% "N"

beginchar (174,1.3wm,wm,0pt#);grid;
dypm((w/2,dphaut)..(slarge,.6dphaut)..(w/2,0)..(w-slarge,.5dphaut)..cycle,0.9,1);

endchar;%%% "O"

beginchar (175,1.2wm,wm,0pt#);grid;
dypm((1.5slarge,dphaut)--(slarge,0),0.9,1);
dypm(((.5slarge,dphaut){right}..{left}(slarge,4/7dphaut))xscaled 1.6,0.9,1);charwd:=charwd-slarge#;w:=w-slarge;
endchar;%%% "P"

beginchar (176,1.3wm,wm,0pt#);grid;
dypm((w/2,dphaut)..(slarge,.6dphaut)..(w/2,0)..(w-slarge,.5dphaut)..cycle,0.9,1);
dypm((w/2,2shaut)--(3w/4,-2shaut),0.9,1);
endchar;%%% "Q"

beginchar (177,1.2wm,wm,0pt#);grid;
dypm((.slarge,dphaut)--(.6slarge,0),0.9,1);
dypm(((.1slarge,dphaut){right}..{left}(slarge,4/7dphaut))xscaled 1.5,0.9,1);
dypm((1.5slarge,4.2/7dphaut)--(w-slarge,.1shaut),0.9,1);charwd:=charwd-.5slarge#;w:=w-.5slarge;
endchar;%%% "R"

beginchar (178,1.wm,wm,0pt#);grid;
dypm((w-slarge,dphaut-.5shaut){dir 155}..tension.9..{dir-25}(w/2,4/7dphaut)..{left}(2.5slarge,0)..(0,shaut),0.9,1);
endchar;%%% "S"

beginchar (179,1.wm,wm,0pt#);grid;
dypm((w/2,dphaut-.2shaut)--(w/2,-.3shaut),0.9,1);
pickup lspen;
draw((slarge,dphaut-.2shaut)--(w-slarge,dphaut-.2shaut));
endchar;%%% "T"

beginchar (180,1.2wm,wm,0pt#);grid;
dypm((slarge,dphaut)--(slarge,4/7dphaut){down}...{right}(w/2,0),0.9,1);
dypm((w-slarge,dphaut){down}...{left}(w/2,0),0.9,1);

endchar;%%% "U"

beginchar (181,1.2wm,wm,0pt#);grid;
dypm((slarge,dphaut)--(w/2,0),0.9,1);
dypm((w-slarge,dphaut)--(w/2,0),0.9,1);

endchar;%%% "V"

beginchar (182,1.5wm,wm,0pt#);grid;
dypm((slarge,dphaut)--(w/3,0)--(w/2,dphaut/2),0.9,1);
dypm((w-slarge,dphaut)--(2w/3,0),0.9,1);
dypm((w/2,dphaut/2)--(2w/3,0),0.9,1);

endchar;%%% "W"

beginchar (183,1.2wm,wm,0pt#);grid;
dypm((w-slarge,dphaut)--(slarge,0),0.9,1);
dypm((slarge,dphaut)--(w-slarge,0),0.9,1);
endchar;%%% "X"

beginchar (184,1.2wm,wm,0pt#);grid;
dypm((w-slarge,dphaut)--(w/2,4/7dphaut),0.9,1);
dypm((slarge,dphaut)--(w/2,4/7dphaut),0.9,1);
dypm((w/2,4/7dphaut)--(w/2,-.3shaut),0.9,1);
endchar;%%% "Y"

beginchar (185,1.2wm,wm,0pt#);grid;
dypm((slarge,dphaut-.4shaut)--(w-slarge,dphaut-.4shaut),0.9,1);
dypm((slarge,0)--(w-slarge,0),0.9,1);

dypm((w-slarge,dphaut-.4shaut)--(slarge,0),0.9,1);

endchar;%%% "Z"

beginchar (186,1.wm,wm,0pt#);grid;
dypm((1.5slarge,dphaut)--(slarge,0),0.9,1);
pickup lspen;
draw((1slarge,dphaut)--(w-slarge,dphaut));
draw((1slarge,0)--(w-slarge,0));
draw((1slarge,4/7dphaut)--(2w/3,4/7dphaut));sh(3w/4);vsh(dhaut/2);
aigu;sh(-3w/4);vsh(-dhaut/2);
endchar;%%% "‚"

beginchar (187,1.wm,wm,0pt#);grid;
dypm((1.5slarge,dphaut)--(slarge,0),0.9,1);
pickup lspen;
draw((1slarge,dphaut)--(w-slarge,dphaut));
draw((1slarge,0)--(w-slarge,0));

draw((1slarge,4/7dphaut)--(2w/3,4/7dphaut));
sh(3w/4);vsh(dhaut/2);grave;
sh(-3w/4);vsh(-dhaut/2);

endchar;%%% "Š"




beginchar (188,1.wm,wm,0pt#);grid;
dypm((1.5slarge,dphaut)--(slarge,0),0.9,1);
pickup lspen;
draw((1slarge,dphaut)--(w-slarge,dphaut));
draw((1slarge,0)--(w-slarge,0));

draw((1slarge,4/7dphaut)--(2w/3,4/7dphaut));sh(3w/4);vsh(dhaut/2);cflex;

sh(-3w/4);vsh(-dhaut/2);
endchar;%%% "ˆ"

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%%%%%%%% accents...
vsh(-4.75wm);sh(3.55wm);

beginchar (0 ,1.5wm,-wm,0);grid;
aigu;endchar;% "\'"
beginchar (1 ,1.5wm,-wm,0);grid;
grave;endchar;% "\`"
beginchar (2 ,1.5wm,-wm,0);grid;
cflex;endchar;% "\^"

beginchar (3,1.5wm,-wm,0);grid;
tilde;endchar;% "\~"

beginchar (4,1.5wm,-wm,0);grid;
trema;endchar;% "\~"

vsh(4.75wm);sh(-3.55wm);

%%%%%%%%% "queues" initiales %%%%%%%%%%%%%%%%
beginchar(131,0.35wm,0,0); grid;
dyp(z.i-(0,.7shaut){dir20}..{dir (liangle+10)}z.f+(0,.7shaut));
endchar;

beginchar(132,0.30wm,0,0); grid;
dyp(z.i{dir30}..{dir (liangle+10)}(w+.5mdel,y'4));

endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

olarge:=1.7olarge;
begingroup
%save angledyn;
%angledyn:=-20; 
ohaut:=1.04ohaut;


beginchar ("e",0.87wm,wm,0pt#);Grid;
eboucle;endchar;


olarge:=olarge/1.15;

%%%%%%%%%%% modification de "e" (avant m,n, etc.)

beginchar (150,0.87wm,wm,0pt#);Grid;
evboucle;endchar; %%%% e

beginchar (151,0.87wm,wm,0pt#);Grid;
evboucle;grave;endchar; %%%%%%%%%% Š

beginchar (152,0.87wm,wm,0pt#);Grid;
evboucle;aigu;endchar; %%%%%%%%%% ‚

beginchar (128,0.87wm,wm,0pt#);Grid;
evboucle;etrema;endchar; %%%%%%%%%%%%% ‰

beginchar (158,0.87wm,wm,0pt#);Grid;
evboucle;vsh(1pt);cflex;vsh(-1pt);endchar; %%%%%%%% ˆ

olarge:=olarge*1.15;

%%%%%%%%%% e accentu‚ (conventions dcr)

beginchar (232,0.87wm,wm,0pt#);Grid;
eboucle;grave;endchar; %%%%%%%%%%%%%% Š

beginchar (233,0.87wm,wm,0pt#);Grid;
eboucle;aigu;endchar; %%%%%%%%%% ‚

beginchar (234,0.87wm,wm,0pt#);Grid;
eboucle;vsh(1pt);cflex;vsh(-1pt);endchar; %%%%%%%% ˆ

beginchar (235,0.87wm,wm,0pt#);Grid;
eboucle;etrema;endchar; %%%%%%%%%%%%% ‰





olarge:=(1.5/(1.2*1.7))*olarge;
ohaut:=(1.07ohaut/1.04);


angledyn:=55;
beginchar ("s",0.83wm,wm,0pt#);Grid;
essvar; endchar;
olarge:=(1.2/1.3)*olarge;

beginchar (139,0.80wm,wm,0pt#);Grid;
essovar; endchar; %%%%%%%%%%% s aprŠs o, b etc.
olarge:=(1.2/1.3)*olarge;
ohaut:=(ohaut/1.07);


endgroup;

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%


beginchar ("o",1.57olarge#,wm,0pt#);grid;%1.45
ovve;endchar;

beginchar (143,1.57olarge#,wm,0pt#);grid;%1.45
ovvn;charwd:=charwd+.2slarge#;w:=w+.2slarge;
endchar; %%%%%%%%% o avant n, v, etc.

beginchar (244,1.57olarge#,wm,0pt#);grid;
ovve;vsh(1pt);oflex;vsh(-1pt);endchar; %%%%%% “

beginchar (246,1.57olarge#,wm,0pt#);grid;
ovve;x'10:=x'10+0.7slarge;etrema;endchar;%%%% ”

olarge:=1.7olarge;

beginchar (247,1.3wm,wm,0pt#);Grid;
oevale;endchar; %%%%%%%%%%%%% \oe (o,e dans l'o)

olarge:=(1/1.7)*olarge;


beginchar ("a",wm,wm,0pt#);agrid;
aovale;abarre;endchar;

beginchar (134,wm+.5slarge#,wm,0pt#);agrid;
aovale;avbarre;endchar;%%%%%%%%%% a avant v...


%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%


beginchar ("b",0.84wm,2wm,0pt#);grid;
bbarre;endchar;

beginchar (137,0.84wm,2wm,0pt#);grid;
bbbarre;endchar;%%%%%%%%%% avant b,l

beginchar ("d",wm,2wm,0pt#);agrid;
aovale;dbarre;endchar;



beginchar ("t",0.56wm,2wm,0pt#);grid;
thbarre;tbarre;endchar;

olarge:=1.3olarge; 

beginchar ("l",0.8wm,2wm,0pt#);grid;
lboucle;endchar;

beginchar (136,0.8wm,2wm,0pt#);grid;
lbboucle;endchar; %variante aprŠs b



beginchar ("f",0.67wm,2wm,wm);grid;
fboucle;endchar;

beginchar ("c",0.72wm,wm,0pt#);grid;
cboucle;endchar;

beginchar (133,0.76wm,wm,0pt#);grid;
clboucle;endchar;%%%%%%%%%"c" large avant l,r,t.

beginchar (231,0.72wm,wm,0pt#);grid;
cboucle;save plein; plein:=mdel;cedille;endchar;%%%%%%%%% ‡



olarge:=olarge/1.3;currenttransform:= currenttransform shifted(0.02*unit, 0);




sh(slarge);
fgras:=0.9fgras;
beginchar ("p",0.85wm+1.5slarge#,wm,wm);grid;
penne;
phampe;queue;endchar;

beginchar (155,0.85wm+1.5slarge#,wm,wm);grid;
penne;
phampe;endchar;%%%%%%%%% p sans queue


beginchar ("q",0.98wm,wm,wm);grid;
aqovale;qhampe;queue;endchar;
sh(-slarge);

beginchar (140,0.98wm,wm,wm);grid;
aqovale;qhampe;endchar;%%%%%%%%% q sans queue

fgras:=fgras/0.9;

currenttransform:= currenttransform shifted(-0.9olarge, 0);





beginchar ("v",0.86wm,wm,0pt#);grid;
evve;charwd:=charwd-.15slarge#;w:=w-.15slarge;endchar;

beginchar (144,0.86wm,wm,0pt#);grid;
evve;erasenb;charwd:=charwd-.15slarge#;w:=w-.15slarge;endchar;
%%%%%%%%% v modifi‚ aprŠs n

currenttransform:= currenttransform shifted(2.4olarge, 0);


currenttransform:= currenttransform shifted(-0.66olarge, 0);

beginchar ("x",1.15wm,wm,0pt#);grid;sh(.9slarge)
cxboucle;xboucle;sh(-.9slarge);charwd:=charwd+.9slarge#;w:=w+.9slarge;endchar;

beginchar (145,1.15wm,wm,0pt#);grid;sh(.9slarge)
cxboucle;oxboucle;sh(-.9slarge);charwd:=charwd+.9slarge#;w:=w+.9slarge;endchar;
%%%%%%%%%% x modifi‚ aprŠs n

currenttransform:= currenttransform shifted(-0.84olarge, 0);

fgras:=(0.93/1.1)*fgras;
beginchar ("u",wm,wm,0pt#);grid;
iobarre;abarre;endchar;


beginchar(252,wm,wm,0pt#);grid;iobarre;abarre;trema;endchar;%%%%%%%%%% �

beginchar ("w",1.35wm,wm,0pt#);grid;
ewe;charwd:=charwd+.8slarge#;w:=w+.8slarge;endchar;

beginchar (249,wm,wm,0pt#);grid;
iobarre;abarre;agrave;endchar;%%%%%%%% —

beginchar (251,wm,wm,0pt#);grid;
iobarre;abarre;sh(-0.5pt); vsh(1pt);oflex;sh(0.5pt);vsh(-1pt);endchar;%%%%% –

fgras:=(1.1/0.93)*fgras;



beginchar (224,wm,wm,0pt#);agrid;
aovale;abarre;agrave;endchar;%%%%%%%%% "…"



beginchar (226,wm,wm,0pt#);agrid;
aovale;abarre;vsh(1pt);aflex;vsh(-1pt);endchar;%%%%%%%% ƒ

beginchar (228,wm,wm,0pt#);agrid;
aovale;abarre;trema;endchar;%%%%%%%%% „


beginchar ("-",1.5wm,wm,0pt#);grid;

pickup mmfpen; draw (w/4,y0)--(3w/5,y0);endchar;

beginchar (22,2.5wm,wm,0pt#);grid;

pickup mmfpen; draw (w/4,y0)--(3w/5,y0);endchar;

beginchar (23,3.5wm,wm,0pt#);grid;

pickup mmfpen; draw (w/4,y0)--(3w/5,y0);endchar;

beginchar ("=",1.5wm,wm,0pt#);grid;
vsh(.2ohaut);
pickup mmfpen; draw (w/4,y0)--(3w/5,y0);
pickup mmfpen; draw (w/4,0)--(3w/5,0)
;vsh(-.2ohaut);
endchar;



beginchar ("z",0.85wm,wm,0pt#);grid;
zed; charwd:=charwd+1.5slarge#;w:=w+1.5slarge;endchar;

beginchar (130,0.85wm,wm,0pt#);grid;
ozed;charwd:=charwd+1.5slarge#;w:=w+1.5slarge; endchar;%%%%%%%%%% z modifi‚ aprŠs o

sh(slarge);
beginchar ("n",0.85wm+slarge#,wm,0pt#);agrid;
sh(.5slarge);enne;sh(-3.5slarge);nvbarre;sh(3slarge);charwd:=charwd+.8slarge#;w:=w+.8slarge;endchar;

beginchar (241,0.85wm+slarge#,wm,0pt#);agrid;
sh(.5slarge);enne;tilde;sh(-3.5slarge);nvbarre;sh(3slarge);charwd:=charwd+.8slarge#;w:=w+.8slarge;endchar;%%% n tilde espagnol

beginchar (141,0.85wm+slarge#,wm,0pt#);agrid;
sh(.5slarge);enne;sh(-3.5slarge);nvbarre;erasenb;sh(3slarge);charwd:=charwd+.8slarge#;w:=w+.8slarge;endchar;%%%%%%%%%% n modifi‚ aprŠs o

beginchar (148,0.85wm+slarge#,wm,0pt#);agrid;
sh(.5slarge);enne;tilde;sh(-3.5slarge);nvbarre;erasenb;sh(3slarge);charwd:=charwd+.8slarge#;w:=w+.8slarge;endchar;%%%%%%%%%% n tilde modifi‚ aprŠs o

beginchar ("m",1.42wm,wm,0pt#);grid;
sh(.5slarge);emme;sh(-3.5slarge);nvbarre;sh(3slarge);charwd:=charwd+1.1slarge#;w:=w+1.1slarge;endchar;



beginchar (142,1.42wm,wm,0pt#);grid;
sh(.5slarge);emme;sh(-3.5slarge);nvbarre;erasenb;sh(3slarge);charwd:=charwd+1.1slarge#;w:=w+1.1slarge;endchar;
sh(-slarge); %%%%%%%%%%%%% m modifi‚ aprŠs o

beginchar ("r",0.87wm,wm,0pt#);grid;
errevar;endchar;

beginchar (129,0.87wm,wm,0pt#);grid;
errevor;endchar; %%%%%%%% r modifi‚ aprŠs o

beginchar ("h",0.95wm+0.9slarge#+mdel#,2wm,0pt#);agrid;
sh(mdel);x.f:=x.f-(mdel);enne;sh(-mdel);hbarre;charwd:=charwd-1.7mdel#;w:=w-1.7mdel;endchar;

beginchar ("k",0.95wm+0.9slarge#+mdel#,2wm,0pt#);agrid;
sh(mdel); x.f:=x.f-(mdel);ekke;sh(-mdel);hbarre;charwd:=charwd+mdel#;w:=w+mdel;endchar;


ohaut :=2ohaut; 
olarge :=1.2olarge; 
obar :=bar; bar :=plein; 
olarge :=1.2olarge; 

beginchar ("C", 1.52wm, 2wm, 0pt#); Grid; dypm((0,dhaut)..(-slarge,.9dhaut){down}..(0,.8dhaut){dir-35}.. (5w/12,.73dhaut)..
{up}(5w/6,0.9dhaut),.7,1);
dyp((5w/6,0.9dhaut){up}..{left}(2w/3,dhaut)..%(w/2.5,dhaut/2)..
(2w/3,0){right}..{dir liangle}z.f); 
 
 endchar; 

beginchar (199, 1.52wm, 2wm, 0pt#); Grid; dypm((0,dhaut)..(-slarge,.9dhaut){down}..(0,.8dhaut){dir-35}.. (5w/12,.73dhaut)..
{up}(5w/6,0.9dhaut),.7,1);
dyp((5w/6,0.9dhaut){up}..{left}(2w/3,dhaut)..%(w/2.5,dhaut/2)..
(2w/3,0){right}..{dir liangle}z.f);sh(w/2.5);save plein; plein:=mdel;Cedille;sh(-w/2.5); 
 endchar; %%% ‡ majuscule


beginchar ("G", 1.52wm, 2wm, wm); Grid;z150+z100=2z0=z350+z300=z850+z800;z'100=(0,0);z'''5=z5+(olarge-slarge,ohaut/4);z90-z0=z'150-z150=(olarge,0);z'350-z350=z'850-z850=(olarge-2slarge,0);z''100-z'100=(olarge-slarge,0);
dypm((z4-(0,2/3y4){down}..z'150..z'350..z'850..tension4..{dir liangle}z.f)shifted(1.5slarge,0),0.9,1);%z''100
 dypm((0,dhaut)..(-slarge,.9dhaut){down}..(0,.8dhaut){dir-35}.. (5w/12,.73dhaut)..
{up}(5w/6,0.9dhaut),.7,1);
dyp((5w/6,0.9dhaut){up}..{left}(2w/3,dhaut)..%(w/2.5,dhaut/2)..
(w/3,0){right}..{up}z4+(1.5slarge,-2/3y4)); 
 charwd:=charwd+1.5slarge#;w:=w+1.5slarge;
 endchar; 
beginchar ("Y", 1.52wm, 2wm, wm); Grid;z150+z100=2z0=z350+z300=z850+z800;z'100=(0,0);z'''5=z5+(olarge-slarge,ohaut/4);z90-z0=z'150-z150=(olarge,0);z'350-z350=z'850-z850=(olarge-2slarge,0);z''100-z'100=(olarge-slarge,0);
sh(x4-4w/5+1.5slarge);
dyp((0,3dhaut/5){left}..{up}(-w/5,4dhaut/5)..(0.3w/5,dhaut){right}..tension1.5..{right}(1.6w/5,0)..tension1.5..{up}(4w/5,dhaut));
sh(-x4+4w/5-1.5slarge);

dypm(((x4,dhaut){down}..z'150..z'350..z'850..tension4..{dir liangle}z.f)shifted(1.5slarge,0),0.9,1);%z''100


 charwd:=charwd+1.5slarge#;w:=w+1.5slarge;
 endchar; 
beginchar ("T", 1.6wm, 2wm, 0pt#); Grid; 
 dyp((slarge,.8dhaut).. (0,.9dhaut){up}..(w/3,dhaut)..tension 1.6..{right}(2w/3,.8dhaut)..(5w/6,0.9dhaut){up}..{left}(2w/3,dhaut)..(w/3,dhaut/2)..(2w/3,0){right}..{dir liangle}z.f); endchar; 


olarge :=olarge/1.2; 


beginchar ("E",1.42wm,2wm, 0pt#); Grid; 
 dyp((0,dhaut)..(-slarge,.9dhaut){down}..(0,.8dhaut){dir-35}.. (w/3,.73dhaut)..
{up}(2w/3,0.9dhaut));
dyp((2w/3,0.9dhaut){up}..{left}(8w/15,dhaut)..{dir -20}(w/2,2.9dhaut/5)..{up}(.6w,2.9dhaut/5)..
{dir 160}(w/2,3dhaut/5));
dyp((w/2,3dhaut/5){dir 160}..
(2w/3,0){right}..{dir liangle}z.f); 
 
 endchar; 

beginchar (200, 1.42wm, 2wm, 0pt#); Grid; dshaut:=0.93dhaut; 
 dyp((0,dshaut)..(-slarge,.9dshaut){down}..(0,.8dshaut){dir-35}.. (w/3,.73dshaut)..
{up}(2w/3,0.9dshaut));
dyp((2w/3,0.9dshaut){up}..{left}(8w/15,dshaut)..{dir -20}(w/2,2.9dshaut/5)..{up}(.6w,2.9dshaut/5)..
{dir 160}(w/2,3dshaut/5));
dyp((w/2,3dshaut/5){dir 160}..
(2w/3,0){right}..{dir liangle}z.f); 
 sh(2.5slarge);vsh(1.13dhaut-y103-shaut); Grave;vsh(-1.13dhaut+y103+shaut);sh(-2.5slarge);
 endchar; %%%% Š majuscule

beginchar (201, 1.42wm, 2wm, 0pt#); Grid; dshaut:=0.93dhaut; 
 dyp((0,dshaut)..(-slarge,.9dshaut){down}..(0,.8dshaut){dir-35}.. (w/3,.73dshaut)..
{up}(2w/3,0.9dshaut));
dyp((2w/3,0.9dshaut){up}..{left}(8w/15,dshaut)..{dir -20}(w/2,2.9dshaut/5)..{up}(.6w,2.9dshaut/5)..
{dir 160}(w/2,3dshaut/5));
dyp((w/2,3dshaut/5){dir 160}..
(2w/3,0){right}..{dir liangle}z.f); 
 sh(2.6slarge);vsh(1.16dhaut-y103-shaut); aigu;vsh(-1.16dhaut+y103+shaut);sh(-2.6slarge);
 endchar; %%%%%% ‚ majuscule

beginchar (202, 1.42wm, 2wm, 0pt#); Grid; dshaut:=0.93dhaut; 
 dyp((0,dshaut)..(-slarge,.9dshaut){down}..(0,.8dshaut){dir-35}.. (w/3,.73dshaut)..
{up}(2w/3,0.9dshaut));
dyp((2w/3,0.9dshaut){up}..{left}(8w/15,dshaut)..{dir -20}(w/2,2.9dshaut/5)..{up}(.6w,2.9dshaut/5)..
{dir 160}(w/2,3dshaut/5));
dyp((w/2,3dshaut/5){dir 160}..
(2w/3,0){right}..{dir liangle}z.f); 
 sh(2.6slarge);vsh(1.16dhaut-y103-shaut);cflex;vsh(-1.16dhaut+y103+shaut);sh(-2.6slarge);
 endchar; %%%%%%%%%%% ˆ majuscule


ohaut:=ohaut/2;
olarge:=olarge/1.2;bar:=obar;


beginchar ("i",0.71wm-.3slarge#,1.2wm,0pt#);grid;sh(.7slarge);
ibarre;ipoint;sh(-.7slarge);iqueue;endchar;

%%%%%%%%%%%%%%%%%%%%%%%% i modifi‚s


beginchar (153,0.71wm+.2slarge#,1.2wm,0pt#);grid;sh(.7slarge);
ivbarre;ipoint;sh(-.7slarge);iqueue;endchar; 
beginchar (154,0.71wm+.2slarge#,1.2wm,0pt#);grid;sh(.8slarge);
ivbarre;ipoint;sh(-.8slarge);endchar;

beginchar (156,0.71wm-.3slarge#,1.2wm,0pt#);grid;sh(.7slarge);
ivbarre;sh(-.7slarge);iqueue;iflex;endchar;%%%%%%%%%%%% Œ modifi‚

beginchar (157,0.71wm-.3slarge#,1.2wm,0pt#);grid;sh(.7slarge);
ivbarre;sh(-.7slarge);iqueue;itrema;endchar;%%%%%%%%%%‹ modifi‚


sh(slarge)

beginchar (135,0.71wm+.7slarge#,1.2wm,0pt#);grid;
iibarre;ipoint;endchar;%version sans queue pour "o"
%%%%%%%%%%%
sh(-slarge)

beginchar (238,0.71wm-.3slarge#,1.2wm,0pt#);grid;sh(.7slarge);
ibarre;sh(-.7slarge);iqueue;iflex;endchar;%%%%%%%%%%%% Œ

beginchar (239,0.71wm-.3slarge#,1.2wm,0pt#);grid;sh(.7slarge);
ibarre;sh(-.7slarge);iqueue;itrema;endchar;%%%%%%%%%%‹

beginchar (147,0.71wm-.3slarge#,1.2wm,0pt#);grid;sh(.7slarge);
ibarre;sh(-.7slarge);iflex;endchar;%%%%%%% Œ modifi‚ 
%%%%%%%% (en place dcr du i accent grave)

beginchar (146,0.71wm-.3slarge#,1.2wm,0pt#);grid;sh(.7slarge);
ibarre;sh(-.7slarge);itrema;endchar;%%%%%%% ‹ modifi‚ 
%%%%%%%% (en place dcr du i accent aig�)


currenttransform:= currenttransform shifted(-0.35*unit, 0);



beginchar ("j",0.6wm,1.1wm,wm);grid;
jboucle;jpoint;jqueue;endchar;

beginchar (138,0.6wm,1.1wm,wm);grid;
jboucle;jpoint;endchar; %% j sans queue

currenttransform:= currenttransform shifted(0.35*unit, 0);

beginchar ("g",0.92wm,1.2wm,wm);grid;
gboucle;aovale;endchar;

beginchar ("y",0.92wm,1.2wm,wm);grid;
gboucle;iobarre;endchar;


%%%%%%%%%%%% chiffres

beginchar ("0",0.60wm,wm,0);
dyp((w/2,thaut){left}..tension1.2..{down}(0,2.2thaut/4)..tension1.2..{right}(w/2,0)..tension1.2..{up}(w,2thaut/4)..tension1.2..{dir169}(w/2,thaut));
endchar;

beginchar ("1",1.10wm,wm,0);
dyp((w/4,3thaut/5){dir 50}..{up}(w/2,thaut));
z1=(w/2,thaut);z2=(.85w/2,0);penpos1(delie,0);penpos2(1.1plein,0);
penstroke(z1e{dir-110}..{down}z2e);charwd:=charwd-slarge#;w:=w-slarge;
endchar;

beginchar ("2",0.80wm,wm,0);
dyp((w/6,2thaut/3){up}..{right}(w/2,thaut)..{down}(5w/6,2thaut/3)..{down}(0,0));
dyp((0,0){up}..{right}(w/4,shaut)..{right}(2w/3,0)..(w,shaut));

endchar;

currenttransform:=currenttransform xscaled .85 slanted 1/6;


beginchar ("3",0.9wm,wm,0);
dyp((0,4thaut/5)..(w/4.5,thaut){right}..tension 1.2..{left}(w/3+.5slarge,3thaut/5-.2shaut)..{up}(w/3-.5slarge,3thaut/5-.1shaut)..{dir-15}(w/3+.7slarge,3thaut/5+.1shaut)..{left}(w/2,0)..(0,thaut/3));
endchar;

currenttransform:=currenttransform slanted -1/6 xscaled 1/.85 ;

beginchar ("4",1.10wm,wm,0);
dyp((0,3thaut/8){dir 50}..{up}(w/2,thaut));
z1=(w/2,thaut);z2=(w/2,0);penpos1(delie,0);penpos2(1.1plein,0);
penstroke(z1e{dir-110}..{down}z2e);
dyp(((0,0){up}..{right}(w/3,shaut/2)..{right}(2w/3,0)..(5w/6,shaut/3))shifted(0,3thaut/8));
endchar;

currenttransform:=currenttransform xscaled 0.62 slanted 1/4;
sh(1.5slarge);
beginchar ("5",wm,wm,0);
dyp((0,thaut)..(3w/5,thaut));
dyp((0,thaut){down}..(-w/20,3thaut/5));
dypm((0,3thaut/5){dir 20}..(w,thaut/5)..(w/2,-0.shaut)..(0,thaut/5),1.3,1)
endchar;charwd:=charwd+1.5slarge#;w:=w+1.5slarge;
sh(-1.5slarge);

currenttransform:=currenttransform xscaled 1.1;
sh(-slarge);
beginchar ("9",1.10wm,wm,0);
dypm((w/2,thaut){left}..{right}(w/2,3thaut/5)..(4w/5,3.5thaut/5),0.7,1);
dypm((w/2,thaut){right}..(w,3thaut/5)..{left}(3w/4,.2shaut)..{dir130}(w/4,thaut/5),1.4,1);charwd:=charwd-slarge#;w:=w-slarge;
endchar;

beginchar ("6",1.10wm,wm,0);
angledyn:= angledyn+20;
dypm((reverse((w/3,thaut-.2shaut){left}..{right}(w/2,3thaut/5)..(4w/5,3.5thaut/5))) rotatedaround((w/2,thaut/2),180),0.7,1);
dypm((reverse((w/3,thaut){right}..(w,3thaut/5)..(3w/4,.2shaut)..(w/2,.3shaut))) rotatedaround((w/2,thaut/2),180) ,1.2,1);charwd:=charwd-2.5slarge#;w:=w-2.5slarge;
angledyn:= angledyn-20;
endchar;

sh(slarge);
currenttransform:=currenttransform xscaled 1/1.1;

currenttransform:=currenttransform  slanted -1/4 xscaled 1/0.62;

beginchar ("7",1.10wm,wm,0);
dyp((w/5,thaut){dir -20}..{dir20}(4w/5,thaut));
dyp((w/2-w/10,3thaut/5)--(2w/3,3thaut/5));
z1=(3w/4,thaut);z2=(w/2,0);penpos1(delie,0);penpos2(1.1plein,0);
penstroke(z1e{dir-110}..{down}z2e);
endchar;

currenttransform:=currenttransform xscaled 1.2 shifted (-slarge,0);

beginchar ("8",1.10wm,wm,0);
dypm((w/2,thaut){left}..(w/2,3thaut/5)..{left}(w/2,0)..(w/2,3thaut/5)..{dir169}(w/2,thaut),0.84,1);
endchar;



currenttransform:=currenttransform shifted (slarge,0) xscaled 1/1.2;



currenttransform:= currenttransform shifted(0.4*unit, 0);

%%%%%%%%%% "guillemets fran‡ais"

beginchar (19, 1.5wm, 0pt#, 0pt#); grid; 
2y600=y601+y602=2y'600; y601=y'601=ohaut+shaut; y602=y'602=dhaut-shaut/2; x600=0; x601=x602=.7slarge; x'600-x600=x'601-x601=x'602-x602=1.4slarge; 
dypm (z602--z600--z601,0.7,1); 
dypm (z'602--z'600--z'601,0.7,1); 
endchar;

beginchar (20, .5wm, 0pt#, 0pt#); grid; 
2y600=y601+y602=2y'600; y601=y'601=ohaut+shaut; y602=y'602=dhaut-shaut/2; x'600=0.5ohaut; x601=x602=0.5ohaut-2.1slarge; x'600-x600=x'601-x601=x'602-x602=1.4slarge; 
dypm (z602--z600--z601,0.7,1); 
dypm (z'602--z'600--z'601,0.7,1); 
endchar; 

%%%%%%%%%%%%%%%%%%% Ponctuation %%%%%%%%%%%

beginchar ("?",0.60 wm, 0pt#, 0pt#); grid; 
dyp((w/6,dhaut/2){left}..{right}(w/3.5,.9dhaut)..(w/2,dhaut/2)..{down}(w/3,2shaut));
pickup llpen; drawdot (2w/5, 0); endchar; 


beginchar (190,0.60 wm, 0pt#, 0pt#); grid; 
dyp(reverse(((w/6,2dhaut/3){left}..{right}(w/3.5,1.1dhaut)..(w/2,dhaut/2)..{down}(w/3,2shaut)) rotatedaround ((w/2,dhaut/2.5), 180)));
pickup llpen; drawdot (3w/5, dhaut);charwd:=charwd+1.2wm;w:=3w; endchar; 
%% "?" renvers‚


beginchar ("!",0.60 wm, 0pt#, 0pt#);  z1=(w/3,.9dhaut);z2=(w/3,2shaut);
penpos1(1.2plein,0); penpos2(0.6plein,0);
penstroke(z1e--z2e);

pickup llpen; drawdot (w/3, 0); drawdot(z1); endchar; 

beginchar (189,0.60 wm, 0pt#, 0pt#);  z1=(w/3,-.2shaut);z2=(w/3,.8dhaut);
penpos1(1.2plein,0); penpos2(0.6plein,0);
penstroke(z1e--z2e);

pickup llpen; drawdot (w/3, .8dhaut+2.2shaut); drawdot(z1);charwd:=charwd+.9wm;w:=2.5w; endchar; 
%% "!" renvers‚





beginchar (".",0.5 wm, 0pt#, 0pt#); grid; 
pickup llpen; drawdot (w/2, 0); endchar; 


beginchar (",", 0.5wm, 0pt#, 0.2wm); grid; 
pickup lpen; drawdot (w/2, 0); 
dypm((w/2, 0) {down}..{dir225} (w/2-slarge, -2shaut),1,0); endchar; 

beginchar ("+", 2.5wm, 0pt#, 0); grid; sh(-2pt);
 
pickup mfpen; 
draw (w/2,1/5ohaut)--(w/2,6/5ohaut);
draw (w/2-ohaut/2,7/10ohaut)--(w/2+ohaut/2,7/10ohaut); sh(2pt);


; endchar; 

beginchar ("*", 0.3wm, 0pt#, 0); grid; path bars;
bars:= (-w/3,dhaut-2shaut)--(4w/3,dhaut-2shaut);
z.mi=(w/2,dhaut-2shaut);
 
pickup mfpen; 
draw bars;
draw bars rotatedaround (z.mi,60);
draw bars rotatedaround (z.mi,1200);

charwd:=2.7charwd;w:=2.7w;

; endchar; 




beginchar ("/", 0.8wm, 0pt#, 0); grid;  sh(-2pt);
pickup mfpen;
draw (w/5,0)--(4w/5,thaut);sh(2pt)
; endchar; 

beginchar ("%", 0.8wm, 0pt#, 0); grid;  
pickup mfpen;
draw (w/5,0)--(4w/5,thaut); dypm(fullcircle scaled slarge shifted (w/5,thaut-shaut), 0.8,1);dypm(fullcircle scaled slarge shifted (4w/5,shaut), 0.8,1); endchar; 


beginchar (";", 0.5wm, 0pt#, 0.2wm); grid;
pickup lpen; drawdot (w/2, 0); 
dypm((w/2, 0) {down}..{dir225} (w/2-slarge, -2shaut),1,0);
pickup lpen; drawdot (w/2, 2ohaut/3); endchar; 

currenttransform := currenttransform shifted (-0.4*unit, 0); 

beginchar (":", 0.2wm, .5wm, 0pt#); grid; 
pickup lpen; drawdot (-2slarge, 0); drawdot (-2slarge, 2ohaut/3); endchar; 


beginchar ("'",0.5wm,0pt#,0.2wm);grid;
dypm( (slarge,dhaut+shaut){down}..{dir225} (0,dhaut-shaut),0.85,1);endchar;

beginchar ("`",0.5wm,0pt#,0.2wm);grid;
dypm( (0,dhaut+shaut){down}..{dir315} (slarge,dhaut-shaut),0.85,1);endchar;

beginchar (16,0.5wm,0pt#,0.2wm);grid;
dypm( (0,dhaut+shaut){down}..{dir315} (slarge,dhaut-shaut),0.85,1);dypm( (2slarge,dhaut+shaut){down}..{dir315} (3slarge,dhaut-shaut),0.85,1);endchar;

beginchar (17,0.5wm,0pt#,0.2wm);grid;
dypm( (slarge,dhaut+shaut){down}..{dir225} (0,dhaut-shaut),0.85,1);dypm( (3slarge,dhaut+shaut){down}..{dir225} (2slarge,dhaut-shaut),0.85,1);endchar;


beginchar (18 ,0.5wm,0pt#,0.2wm);grid;
dypm( (slarge,thaut+shaut){down}..{dir225} (0,thaut-shaut),0.85,1);endchar; % apostrophe "basse", rempla‡ant",,"


beginchar("(", 0.6wm,1.5wm,-0.25wm); grid; angledyn:=20;
dypm((slarge,dhaut)..(0,shaut)..(slarge,-dhaut/3),1,-2);
endchar;

beginchar(")", 0.6wm,1.5wm,-0.25wm); grid; dypm((0,dhaut)..(2slarge,shaut)..(0,-dhaut/3)shifted (0.3ux,0),1,-2);
endchar;

currenttransform := currenttransform shifted (0.4*unit, 0); 



%%%%%%%%% Ligatures et "kerning" %%%%%%%%%%%%%%%%

%%%%%%%%% ligatures "standards" des fontes dcr

ligtable "-": "-"=:22;
ligtable 22: "-"=:23;
ligtable "!" : "`"=:189;
ligtable "?" : "`"=:190;
ligtable "'" : "'"=: 17,
               "A" kern 2.5pt#, %%%%%%%%% 
               "U" kern 2pt#;
;
ligtable "`" : "`"=: 16;

%%%%%%%%% "queues" de d‚but de mots

ligtable ||: "a"=:|131,  "e"=:|131, "c"=:|131,  "o"=:|131, "b"=:|131, "f"=:|131, "g"=:|131,  "h"=:|131,"k"=:|131, "l"=:|131, "q"=:|131,  "y"=:|131,"t"=:|132,"u"=:|132,"i"=:|132,  "d"=:|131, 231=:|131, 224=:|131, 233=:|131, 232=:|131, 234=:|131, 247=:|131,"x"=:145;

ligtable 132: "i"|=:135, 135 kern -slarge#;

ligtable 131: "q"|=:140;

%%%%%%%%%% ajustements de formes et kerning

ligtable "o": "b"|=:137, "p"|=:155, "r"|=:129, "z"|=:130,"i"|=:135,"x"|=:145, 239|=:146, 238|=:147,"m"=:|143,"n"=:|143, 241=:|143,"v"=:|143 
,"l"|=:136, "j"|=:138,"q"|=:140, "t" kern 2pt#, "u" kern 1pt#,  "s"|=:139 ,"e" kern 1pt#,"y" kern 1pt#;

ligtable 143:  "v"|=:144,"m"|=:142,"n"|=:141, 241|=:148, 144 kern .5pt#,142 kern .3pt#, 148 kern .3pt#, 141 kern .3pt#;

ligtable 244: "b"|=:137, "p"|=:155, "r"|=:129, "z"|=:130,"i"|=:135,"x"|=:145, 239|=:146, 238|=:147, "l"|=:136, "j"|=:138,"q"|=:140, "t" kern 2pt#, "u" kern 1pt#,  "s"|=:139 ,"e" kern 1pt#,"y" kern 1pt#;

ligtable 246: "b"|=:137, "p"|=:155, "r"|=:129, "z"|=:130,"i"|=:135,"x"|=:145, 239|=:146, "l"|=:136, "j"|=:138,"q"|=:140, "t" kern 2pt#, "u" kern 1pt#,  "s"|=:139 ,"e" kern 1pt#,"y" kern 1pt#;


ligtable "b": "r"|=:129,"z"|=:130, "i"|=:135, "l"|=:136,"b"|=:137,"n"|=:141,241|=:148,"j"|=:138,135 kern -0.2pt#, 136 kern -0.5pt#,137 kern -0.5pt#,138 kern -0.5pt#,"s"|=:139  ,139 kern -0.5pt#, "t" kern 1.7pt#, "u" kern 1pt#, "m" kern 2pt#, "n" kern 5pt#,241 kern 5pt#, "e" kern 0.8pt#, "y" kern 1pt#;

ligtable "v": "r"|=:129, "i"|=:135,135 kern -0.5pt#, "l"|=:136,136 kern-.7pt#, 137 kern -0.5pt#,138 kern -0.5pt#,  "u" kern 1pt#,  "e" kern 0.7pt#, "y" kern 1pt#;

ligtable 144: "r"|=:129, "i"|=:135,135 kern -0.5pt#, "l"|=:136,136 kern-1pt#, 137 kern -0.5pt#,138 kern -0.5pt#,  "u" kern 1pt#,  "e" kern 0.7pt#, "y" kern 1pt#;

ligtable "p": "n" kern 0.1pt#,241 kern 0.1pt#;
ligtable 155: "n" kern 0.1pt#,241 kern 0.1pt#;
ligtable "q": "u" kern 0.4pt#;
ligtable 140: "u" kern -0.4pt#;
ligtable "c": "'"|=:18,"l"=:|133 ,"t"=:|133 ,"r"=:|133, "m" kern 0.8pt#,"n" kern 0.5pt#,241 kern 0.5pt#;
ligtable 133: "l" kern 0.2pt#;
ligtable 231: "'"|=:18, "m" kern 0.7pt#,"n" kern 0.4pt#,241 kern 0.4pt#;
ligtable "d": "'"|=:18 , "m" kern 0.5pt#;
ligtable "g": "n" kern 0.5pt#,241 kern 0.5pt#;
ligtable "j": "'"|=:18 , "e" kern -0.3pt#, "i" kern -0.3pt#;
ligtable 138: "'"|=:18 , "e" kern -0.3pt#, "i" kern -0.3pt#;
ligtable "m": "'"|=:18 , "m" kern 0.5pt#, "n" kern 0.5pt#,241 kern 0.5pt#;
ligtable 142: "'"|=:18 , "m" kern 0.5pt#, "n" kern 0.5pt#,241 kern 0.5pt#;
ligtable "n": "'"|=:18 ,"q"|=:140, "v" kern 1pt#,"r" kern 0.1pt#, "s" kern -0.4pt#,"x" kern -0.2pt#, "z" kern -0.3pt#, "n" kern 0.3pt#,241 kern 0.3pt#;
ligtable 241: "'"|=:18 ,"q"|=:140, "v" kern 1pt#,"r" kern 0.1pt#, "s" kern -0.4pt#,"x" kern -0.2pt#, "z" kern -0.3pt#, "n" kern 0.3pt#,241 kern 0.3pt#;
ligtable 141: "'"|=:18 ,"q" kern 0.5pt#, "v" kern 3pt#,"r" kern 0.5pt#, "s" kern 0.2pt#, "n" kern 0.5pt#;
ligtable 148: "'"|=:18 ,"q" kern 0.5pt#, "v" kern 3pt#,"r" kern 0.5pt#, "s" kern 0.2pt#, "n" kern 0.5pt#;
ligtable "r": "m" kern 0.5pt#, "n" kern 0.5pt#,141 kern 0.5pt#,"v" kern 1.4pt#;
ligtable 129: "m" kern 0.5pt#, "n" kern 0.5pt#,141 kern 0.5pt#, "v" kern 1.4pt#;
ligtable "t": "m" kern 0.3pt#, "n" kern 0.2pt#, 141 kern 0.2pt#, "r" kern -0.2pt#;
ligtable "s": "'"|=:18 ;
ligtable 139: "'"|=:18 ;
ligtable "u": "'"|=:18 ,"m" kern 0.4pt#, "n" kern 0.4pt#,141 kern 0.4pt#,"v" kern 1.7pt#;
ligtable 252: "'"|=:18 ,"m" kern 0.3pt#, "n" kern 0.3pt#,141 kern 0.3pt#,"v" kern 1.7pt#;
ligtable 249: "'"|=:18 ,"m" kern 0.3pt#, "n" kern 0.3pt#,141 kern 0.3pt#,"v" kern 1.7pt#;
ligtable 251: "'"|=:18 ,"m" kern 0.3pt#, "n" kern 0.3pt#,141 kern 0.3pt#,"v" kern 1.7pt#;
ligtable "a": "v"=:|134, "m" kern 0.5pt#, "n" kern 0.5pt#;
ligtable "e": "m"=:|150,"n"=:|150,"v"=:|150,"l" kern 0.2pt#,"u" kern 0.5pt#,"t" kern 0.5pt#, "f" kern 0.5pt#;
ligtable 247: "l" kern 0.2pt#,"u" kern 0.3pt#,"t" kern 0.5pt#, "f" kern 0.5pt#;
ligtable 232: "m"=:|151,"n"=:|151,"v"=:|151,"l" kern 0.2pt#,"u" kern 0.5pt#,"t" kern 0.5pt#, "f" kern 0.5pt#;
ligtable 233: "m"=:|152,"n"=:|152,"v"=:|152,"l" kern 0.2pt#,"u" kern 0.5pt#,"t" kern 0.5pt#, "f" kern 0.5pt#;
ligtable 234: "m"=:|158,"n"=:|158,"v"=:|158, "v" kern 2.5pt#,"m" kern -0.7pt#,"n" kern -0.7pt#,"l" kern 0.2pt#,"u" kern 0.5pt#,"t" kern 0.5pt#, "f" kern 0.5pt#;
ligtable 235: "m"=:|128,"n"=:|128,"v"=:|128, "v" kern 2.5pt#,"m" kern -0.7pt#,"n" kern -0.7pt# ,"l" kern 0.2pt#,"u" kern 0.5pt#,"t" kern 0.5pt#, "f" kern 0.5pt#;

ligtable 134: "v" kern 0.6pt#;
ligtable 150: "v" kern 0.5pt#,"m" kern -0.7pt#,"n" kern -0.7pt#;
ligtable 151: "v" kern 0.5pt#,"m" kern -0.7pt#,"n" kern -0.7pt#;
ligtable 152: "v" kern 0.5pt#,"m" kern -0.7pt#,"n" kern -0.7pt#;
ligtable 158: "v" kern 0.5pt#,"m" kern -0.7pt#,"n" kern -0.7pt#;
ligtable 128: "v" kern 0.5pt#,"m" kern -0.7pt#,"n" kern -0.7pt#;
ligtable "i": "v"=:|153,"m"=:|153,"n"=:|153; 
ligtable 135: "v"=:|154, "m"=:|154,"n"=:|154;
ligtable 238: "v"=:|156,"m"=:|156,"n"=:|156; 
ligtable 239: "v"=:|157, "m"=:|157,"n"=:|157;
ligtable 147: "v"=:|156,"m"=:|156,"n"=:|156, "e" kern -.5pt#;
ligtable 146: "v"=:|157, "m"=:|157,"n"=:|157, "e" kern -.5pt#;
ligtable 153: "v" kern 0.6pt#,"m" kern 0.1pt#,  "n" kern 0.1pt#;
ligtable 154: "v" kern 0.6pt#,"m" kern 0pt#,  "n" kern 0pt#;
ligtable 156: "v" kern 0.6pt#,"m" kern -0.3pt#,  "n" kern -0.3pt#;
ligtable 157: "v" kern 0.6pt#,"m" kern -0.3pt#,  "n" kern -0.3pt#;
ligtable "l": "m" kern 0.5pt#, "v" kern 1.3pt#, "n" kern 0.5pt#;
ligtable "y": "m" kern 0.4pt#,"v" kern 1.3pt#, "n" kern 0.2pt#;
ligtable 136: "m" kern 0.5pt#, "v" kern 1.3pt#, "n" kern 0.5pt#;
ligtable "k": "i" kern -0.3pt#; 

ligtable "A": "p" kern -.5pt#; 
ligtable "E": "m" kern 0.3pt#,"n" kern 0.4pt#; 
ligtable "L": "'" kern 1pt#; 
ligtable "N": "'" kern 2pt#; 
ligtable "P": "r" kern 1pt#; 



ligtable 18: "A" kern 2pt#, "U" kern 2pt#;


ligtable ".": "1" kern 1pt#,"2" kern 6pt#,"3" kern 6pt#,"4" kern 1pt#,"5" kern 6pt#,"6" kern 7pt#,"7" kern 1pt#,"8" kern 6pt#,"9" kern 6pt#,"0" kern 6pt#;

ligtable ",": "1" kern 1pt#,"2" kern 6pt#,"3" kern 6pt#,"4" kern 1pt#,"5" kern 6pt#,"6" kern 7pt#,"7" kern 1pt#,"8" kern 6pt#,"9" kern 6pt#,"0" kern 6pt#;



ligtable "/": "6" kern 3pt#;


ligtable "0": "0" kern +1.5pt#,"2" kern +1.5pt#,"3" kern +1pt#,"4" kern +1pt#,"6" kern +3pt#,"8" kern -1.5pt#; 

ligtable "1": "1" kern -1.5pt#,"4" kern -.3pt#,"5" kern -1.8pt#,"6" kern +.2pt#,"7" kern -1.5pt#,"8" kern -1.5pt#,"9" kern -1pt#; 

ligtable "2":"2" kern .3pt#, "3" kern 0.5pt#,"5" kern -.6pt#,"6" kern 1.5pt#,"7" kern -.3pt#,"0" kern -.1pt#; 

ligtable "3": "1" kern -.9pt#,"5" kern -1.2pt#,"6" kern 1.2pt#,"7" kern -1pt#,"8" kern -.3pt#; 

ligtable "4": "1" kern -1.4pt#,"4" kern -.2pt#,"5" kern -2.1pt#,"6" kern .2pt#,"7" kern -2pt#,"8" kern -.9pt#,"9" kern -.9pt#; 

ligtable "5":"1" kern -.1pt#,"2" kern .4pt#, "3" kern 0.1pt#,"5" kern -.3pt#,"6" kern 1.7pt#,"7" kern -.2pt#,"0" kern .6pt#; 

ligtable "6": "1" kern -.9pt#,"4" kern -.5pt#,"5" kern -1.2pt#,"6" kern .5pt#,"7" kern -1.1pt#; 

ligtable "7": "1" kern -1.4pt#,"4" kern -.1pt#,"5" kern -1.2pt#,"6" kern .5pt#,"7" kern -.8pt#,"8" kern -1.3pt#;

ligtable "8": "1" kern -1.5pt#,"5" kern -1pt#,"6" kern .2pt#,"7" kern -1.7pt#,"8" kern -.1pt#;

ligtable "9": "1" kern -.6pt#,"5" kern -1.3pt#,"6" kern 1.2pt#,"7" kern -.9pt#,"8" kern -.7pt#,"9" kern -.3pt#; 

%%%%%%%%%% paramètres \fontdimen %%%%%%%%%%%%

% J'ai des doutes.. ma version de TeX semble refuser tout
% changement de ces valeurs.. bref, je les force dans la macro 
% \calli, et de toute façon, cela semble mieux marcher ainsi;
% à toutes fins utiles, ce qui suit est raisonnable.

font_quad=1.5wm;
font_normal_space=2wm;
font_normal_stretch=wm;
font_normal_shrink=0.3wm;

%%%%%% la "design size" n'est pas définie: 128 pt, donc...%%%%%%

end.